developer.intra2net.com Git - libftdi/blob - CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2
   3 # Project
   4 project(libftdi1 C)
   5 set(MAJOR_VERSION 1)
   6 set(MINOR_VERSION 5)
   7 set(PACKAGE libftdi1)
   8 set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION})
   9 set(VERSION ${VERSION_STRING})
  10 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  11
  12 # Support new if() IN_LIST operator
  13 if(POLICY CMP0057)
  14   cmake_policy(SET CMP0057 NEW)
  15 endif()
  16
  17 # Included scripts do automatic cmake_policy() PUSH and POP
  18 if(POLICY CMP0011)
  19   cmake_policy(SET CMP0011 NEW)
  20 endif()
  21
  22 # Target link properties INTERFACE_LINK_OPTIONS, INTERFACE_LINK_DIRECTORIES
  23 # and INTERFACE_LINK_DEPENDS are now transitive over private dependencies
  24 # of static libraries
  25 if(POLICY CMP0099)
  26   cmake_policy(SET CMP0099 NEW)
  27 endif()
  28
  29 # CMake
  30 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  31   set(CMAKE_BUILD_TYPE     RelWithDebInfo)
  32 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  33 set(CMAKE_COLOR_MAKEFILE ON)
  34
  35 add_definitions(-Wall)
  36
  37 include(CMakeOptions.txt)
  38
  39 # Debug build
  40 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  41 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  42   add_definitions(-DDEBUG)
  43 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  44
  45 # find libusb
  46 find_package( PkgConfig )
  47 if (PkgConfig_FOUND)
  48   pkg_check_modules( LIBUSB libusb-1.0 )
  49   if (LIBUSB_FOUND)
  50     include_directories ( ${LIBUSB_INCLUDE_DIRS} )
  51   else()
  52     find_package ( USB1 REQUIRED )
  53     include_directories ( ${LIBUSB_INCLUDE_DIR} )
  54   endif()
  55 endif()
  56
  57 # Find Boost
  58 if (FTDIPP OR BUILD_TESTS)
  59   find_package( Boost REQUIRED )
  60 endif()
  61
  62 # Set components
  63 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  64 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  65 set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries")
  66 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  67
  68 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  69 "Shared library for general use.")
  70 set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION
  71 "Static library, good if you want to embed libftdi1 in your application.")
  72 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  73 "C/C++ header files.")
  74
  75 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  76 set(CPACK_COMPONENT_STATICLIBS_GROUP "Development")
  77 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  78
  79 # guess LIB_SUFFIX, don't take debian multiarch into account
  80 if ( NOT DEFINED LIB_SUFFIX )
  81   if( CMAKE_SYSTEM_NAME MATCHES "Linux"
  82       AND NOT CMAKE_CROSSCOMPILING
  83       AND NOT EXISTS "/etc/debian_version"
  84       AND NOT EXISTS "/etc/arch-release" )
  85     if ( "${CMAKE_SIZEOF_VOID_P}" EQUAL "8" )
  86       set ( LIB_SUFFIX 64 )
  87     endif ()
  88   endif ()
  89 endif ()
  90
  91 if(NOT APPLE)
  92   if(CMAKE_SIZEOF_VOID_P EQUAL 4)
  93     SET(PACK_ARCH "")
  94   else(CMAKE_SIZEOF_VOID_P EQUAL 8)
  95     SET(PACK_ARCH .x86_64)
  96   endif(CMAKE_SIZEOF_VOID_P EQUAL 4)
  97 else(NOT APPLE)
  98   SET(PACK_ARCH "")
  99 endif(NOT APPLE)
 100
 101 # Package information
 102 set(CPACK_PACKAGE_VERSION              ${VERSION_STRING})
 103 set(CPACK_PACKAGE_CONTACT              "Intra2net AG <libftdi@developer.intra2net.com>")
 104 set(CPACK_PACKAGE_DESCRIPTION          "libftdi1 library.")
 105 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION})
 106
 107 # Package settings
 108 if ( UNIX )
 109   set(CPACK_GENERATOR                    "DEB;RPM")
 110   set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
 111   set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
 112   set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})
 113 endif ()
 114
 115 if ( WIN32 )
 116   set ( CPACK_GENERATOR                    "NSIS" )
 117   set ( CPACK_CMAKE_GENERATOR              "MinGW Makefiles" )
 118   set ( CPACK_PACKAGE_NAME                 "${PROJECT_NAME}" )
 119   set ( CPACK_PACKAGE_VENDOR               "" )
 120   set ( CPACK_PACKAGE_INSTALL_DIRECTORY    "libftdi1" )
 121   set ( CPACK_PACKAGE_FILE_NAME            "${PROJECT_NAME}-${VERSION_STRING}-win32")
 122   set ( CPACK_NSIS_DISPLAY_NAME            "libftdi1" )
 123   set ( CPACK_NSIS_MODIFY_PATH             ON )
 124 endif ()
 125
 126 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/LICENSE)
 127
 128 set(CPACK_SOURCE_GENERATOR             TGZ)
 129 set(CPACK_SOURCE_IGNORE_FILES          "\\\\.git;~$;build/")
 130 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION})
 131
 132 # Subdirectories
 133 if ( UNIX )
 134   set ( CPACK_SET_DESTDIR ON )
 135 endif ()
 136
 137 # "make dist" target
 138 set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION_STRING})
 139 add_custom_target(dist
 140     COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
 141             | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
 142     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 143
 144 if ( DOCUMENTATION )
 145   add_subdirectory(doc)
 146 endif ( DOCUMENTATION )
 147
 148 add_subdirectory(src)
 149 if ( FTDIPP )
 150   project(libftdi1 C CXX)
 151   add_subdirectory(ftdipp)
 152 endif ()
 153 if ( PYTHON_BINDINGS )
 154 add_subdirectory(python)
 155 endif ()
 156 if ( FTDI_EEPROM )
 157   add_subdirectory(ftdi_eeprom)
 158 endif ()
 159 if ( EXAMPLES )
 160   add_subdirectory(examples)
 161 endif ()
 162 add_subdirectory(packages)
 163 if ( BUILD_TESTS )
 164   project(libftdi1 C CXX)
 165   add_subdirectory(test)
 166 endif ()
 167
 168 # PkgConfig
 169 set(prefix      ${CMAKE_INSTALL_PREFIX})
 170 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 171 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 172
 173 if(${UNIX})
 174   set(libdir      ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
 175 endif(${UNIX})
 176 if(${WIN32})
 177   set(libdir      ${CMAKE_INSTALL_PREFIX}/bin)
 178 endif(${WIN32})
 179
 180 configure_file(${CMAKE_SOURCE_DIR}/libftdi1.pc.in ${CMAKE_BINARY_DIR}/libftdi1.pc @ONLY)
 181 configure_file(${CMAKE_SOURCE_DIR}/libftdipp1.pc.in ${CMAKE_BINARY_DIR}/libftdipp1.pc @ONLY)
 182 install(FILES ${CMAKE_BINARY_DIR}/libftdi1.pc ${CMAKE_BINARY_DIR}/libftdipp1.pc
 183         DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 184
 185 if (UNIX OR MINGW)
 186   configure_file ( libftdi1-config.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config @ONLY )
 187   install ( PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config
 188             DESTINATION bin )
 189 endif ()
 190
 191 # config script install path
 192 if ( NOT DEFINED LIBFTDI_CMAKE_CONFIG_DIR )
 193   set ( LIBFTDI_CMAKE_CONFIG_DIR lib${LIB_SUFFIX}/cmake/libftdi1 )
 194 endif ()
 195
 196 set ( LIBFTDI_INCLUDE_DIR ${includedir} )
 197 set ( LIBFTDI_INCLUDE_DIRS ${LIBFTDI_INCLUDE_DIR} )
 198 set ( LIBFTDI_LIBRARY ftdi1 )
 199 set ( LIBFTDI_LIBRARIES ${LIBFTDI_LIBRARY} )
 200 list ( APPEND LIBFTDI_LIBRARIES ${LIBUSB_LIBRARIES} )
 201 set ( LIBFTDI_STATIC_LIBRARY ftdi1.a )
 202 set ( LIBFTDI_STATIC_LIBRARIES ${LIBFTDI_STATIC_LIBRARY} )
 203 list ( APPEND LIBFTDI_STATIC_LIBRARIES ${LIBUSB_LIBRARIES} )
 204 if ( FTDIPP )
 205   set ( LIBFTDIPP_LIBRARY ftdipp1 )
 206   set ( LIBFTDIPP_LIBRARIES ${LIBFTDIPP_LIBRARY} )
 207   list ( APPEND LIBFTDIPP_LIBRARIES ${LIBUSB_LIBRARIES} )
 208 endif ()
 209 set ( LIBFTDI_LIBRARY_DIRS ${libdir} )
 210 set ( LIBFTDI_ROOT_DIR ${prefix} )
 211 set ( LIBFTDI_VERSION_STRING ${VERSION_STRING} )
 212 set ( LIBFTDI_VERSION_MAJOR ${MAJOR_VERSION} )
 213 set ( LIBFTDI_VERSION_MINOR ${MINOR_VERSION} )
 214
 215 set ( LIBFTDI_USE_FILE ${CMAKE_INSTALL_PREFIX}/${LIBFTDI_CMAKE_CONFIG_DIR}/UseLibFTDI1.cmake )
 216
 217 include(CMakePackageConfigHelpers)
 218
 219 configure_package_config_file (
 220   cmake/LibFTDI1Config.cmake.in
 221   ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake
 222   INSTALL_DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR}
 223   PATH_VARS
 224     LIBFTDI_USE_FILE
 225     LIBFTDI_ROOT_DIR
 226     LIBFTDI_INCLUDE_DIR
 227     LIBFTDI_INCLUDE_DIRS
 228     LIBFTDI_LIBRARY_DIRS
 229   NO_CHECK_REQUIRED_COMPONENTS_MACRO
 230 )
 231 write_basic_package_version_file (
 232   LibFTDI1ConfigVersion.cmake
 233   VERSION ${LIBFTDI_VERSION_STRING}
 234   COMPATIBILITY AnyNewerVersion
 235 )
 236
 237 install (
 238   FILES
 239     ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake
 240     ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1ConfigVersion.cmake
 241     cmake/UseLibFTDI1.cmake
 242   DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR}
 243 )
 244
 245 include(CPack)
 246
 247 message (STATUS "Summary of build options:
 248
 249   Build static libs: ${STATICLIBS}
 250   Build C++ bindings: ${FTDIPP}
 251   Build Python bindings: ${PYTHON_BINDINGS}
 252   Build ftdi_eeprom: ${FTDI_EEPROM}
 253   Build examples: ${EXAMPLES}
 254   Build tests: ${BUILD_TESTS}
 255   Build API documentation: ${DOCUMENTATION}
 256 ")