developer.intra2net.com Git - libftdi/blob - CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
   2
   3 message(STATUS "CMake version: ${CMAKE_VERSION}")
   4
   5 # Project
   6 project(libftdi1 C)
   7 set(MAJOR_VERSION 1)
   8 set(MINOR_VERSION 5)
   9 set(PACKAGE libftdi1)
  10 set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION})
  11 set(VERSION ${VERSION_STRING})
  12 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  13
  14 # Support new if() IN_LIST operator
  15 if(POLICY CMP0057)
  16   cmake_policy(SET CMP0057 NEW)
  17 endif()
  18
  19 # Included scripts do automatic cmake_policy() PUSH and POP
  20 if(POLICY CMP0011)
  21   cmake_policy(SET CMP0011 NEW)
  22 endif()
  23
  24 # Target link properties INTERFACE_LINK_OPTIONS, INTERFACE_LINK_DIRECTORIES
  25 # and INTERFACE_LINK_DEPENDS are now transitive over private dependencies
  26 # of static libraries
  27 if(POLICY CMP0099)
  28   cmake_policy(SET CMP0099 NEW)
  29 endif()
  30
  31 # CMake
  32 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  33   set(CMAKE_BUILD_TYPE     RelWithDebInfo)
  34 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  35 set(CMAKE_COLOR_MAKEFILE ON)
  36
  37 add_definitions(-Wall)
  38
  39 include(CMakeOptions.txt)
  40
  41 # Debug build
  42 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  43 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  44   add_definitions(-DDEBUG)
  45 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  46
  47 # Find libusb
  48 find_package ( LibUSB REQUIRED )
  49 include_directories ( ${LIBUSB_INCLUDE_DIR} )
  50
  51 # Find Boost
  52 if (FTDIPP OR BUILD_TESTS)
  53   find_package( Boost REQUIRED )
  54 endif()
  55
  56 # Set components
  57 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  58 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  59 set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries")
  60 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  61
  62 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  63 "Shared library for general use.")
  64 set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION
  65 "Static library, good if you want to embed libftdi1 in your application.")
  66 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  67 "C/C++ header files.")
  68
  69 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  70 set(CPACK_COMPONENT_STATICLIBS_GROUP "Development")
  71 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  72
  73 # guess LIB_SUFFIX, don't take debian multiarch into account
  74 if ( NOT DEFINED LIB_SUFFIX )
  75   if( CMAKE_SYSTEM_NAME MATCHES "Linux"
  76       AND NOT CMAKE_CROSSCOMPILING
  77       AND NOT EXISTS "/etc/debian_version"
  78       AND NOT EXISTS "/etc/arch-release" )
  79     if ( "${CMAKE_SIZEOF_VOID_P}" EQUAL "8" )
  80       set ( LIB_SUFFIX 64 )
  81     endif ()
  82   endif ()
  83 endif ()
  84
  85 if(NOT APPLE)
  86   if(CMAKE_SIZEOF_VOID_P EQUAL 4)
  87     SET(PACK_ARCH "")
  88   else(CMAKE_SIZEOF_VOID_P EQUAL 8)
  89     SET(PACK_ARCH .x86_64)
  90   endif(CMAKE_SIZEOF_VOID_P EQUAL 4)
  91 else(NOT APPLE)
  92   SET(PACK_ARCH "")
  93 endif(NOT APPLE)
  94
  95 # Package information
  96 set(CPACK_PACKAGE_VERSION              ${VERSION_STRING})
  97 set(CPACK_PACKAGE_CONTACT              "Intra2net AG <libftdi@developer.intra2net.com>")
  98 set(CPACK_PACKAGE_DESCRIPTION          "libftdi1 library.")
  99 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION})
 100
 101 # Package settings
 102 if ( UNIX )
 103   set(CPACK_GENERATOR                    "DEB;RPM")
 104   set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
 105   set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
 106   set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})
 107 endif ()
 108
 109 if ( WIN32 )
 110   set ( CPACK_GENERATOR                    "NSIS" )
 111   set ( CPACK_CMAKE_GENERATOR              "MinGW Makefiles" )
 112   set ( CPACK_PACKAGE_NAME                 "${PROJECT_NAME}" )
 113   set ( CPACK_PACKAGE_VENDOR               "" )
 114   set ( CPACK_PACKAGE_INSTALL_DIRECTORY    "libftdi1" )
 115   set ( CPACK_PACKAGE_FILE_NAME            "${PROJECT_NAME}-${VERSION_STRING}-win32")
 116   set ( CPACK_NSIS_DISPLAY_NAME            "libftdi1" )
 117   set ( CPACK_NSIS_MODIFY_PATH             ON )
 118 endif ()
 119
 120 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 121
 122 set(CPACK_SOURCE_GENERATOR             TGZ)
 123 set(CPACK_SOURCE_IGNORE_FILES          "\\\\.git;~$;build/")
 124 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION})
 125
 126 # Subdirectories
 127 if ( UNIX )
 128   set ( CPACK_SET_DESTDIR ON )
 129 endif ()
 130
 131 # "make dist" target
 132 set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION_STRING})
 133 add_custom_target(dist
 134     COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
 135       | bzip2 > ${PROJECT_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
 136     WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
 137
 138 add_subdirectory(src)
 139 add_subdirectory(packages)
 140
 141 if ( DOCUMENTATION )
 142   add_subdirectory(doc)
 143 endif ( DOCUMENTATION )
 144
 145 if ( FTDIPP )
 146   project(libftdi1 C CXX)
 147   add_subdirectory(ftdipp)
 148 endif ( FTDIPP )
 149
 150 if ( PYTHON_BINDINGS )
 151   add_subdirectory(python)
 152 endif ( PYTHON_BINDINGS )
 153
 154 if ( FTDI_EEPROM )
 155   add_subdirectory(ftdi_eeprom)
 156 endif ( FTDI_EEPROM )
 157
 158 if ( EXAMPLES )
 159   add_subdirectory(examples)
 160 endif ( EXAMPLES )
 161
 162 if ( BUILD_TESTS )
 163   project(libftdi1 C CXX)
 164   add_subdirectory(test)
 165 endif ( BUILD_TESTS )
 166
 167 # PkgConfig
 168 set(prefix      ${CMAKE_INSTALL_PREFIX})
 169 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 170 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 171
 172 if(${UNIX})
 173   set(libdir      ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR})
 174 endif(${UNIX})
 175 if(${WIN32})
 176   set(libdir      ${CMAKE_INSTALL_PREFIX}/bin)
 177 endif(${WIN32})
 178
 179 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libftdi1.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1.pc @ONLY)
 180 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libftdipp1.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libftdipp1.pc @ONLY)
 181 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libftdi1.pc ${CMAKE_CURRENT_BINARY_DIR}/libftdipp1.pc
 182         DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 183
 184 if (UNIX OR MINGW)
 185   configure_file ( libftdi1-config.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config @ONLY )
 186   install ( PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config
 187             DESTINATION bin )
 188 endif ()
 189
 190 # config script install path
 191 if ( NOT DEFINED LIBFTDI_CMAKE_CONFIG_DIR )
 192   set ( LIBFTDI_CMAKE_CONFIG_DIR ${CMAKE_INSTALL_LIBDIR}/cmake/libftdi1 )
 193 endif ()
 194
 195 set ( LIBFTDI_INCLUDE_DIR ${includedir} )
 196 set ( LIBFTDI_INCLUDE_DIRS ${LIBFTDI_INCLUDE_DIR} )
 197 set ( LIBFTDI_LIBRARY ftdi1 )
 198 set ( LIBFTDI_LIBRARIES ${LIBFTDI_LIBRARY} )
 199 list ( APPEND LIBFTDI_LIBRARIES ${LIBUSB_LIBRARIES} )
 200 set ( LIBFTDI_STATIC_LIBRARY ftdi1.a )
 201 set ( LIBFTDI_STATIC_LIBRARIES ${LIBFTDI_STATIC_LIBRARY} )
 202 list ( APPEND LIBFTDI_STATIC_LIBRARIES ${LIBUSB_LIBRARIES} )
 203 if ( FTDIPP )
 204   set ( LIBFTDIPP_LIBRARY ftdipp1 )
 205   set ( LIBFTDIPP_LIBRARIES ${LIBFTDIPP_LIBRARY} )
 206   list ( APPEND LIBFTDIPP_LIBRARIES ${LIBUSB_LIBRARIES} )
 207 endif ()
 208 set ( LIBFTDI_LIBRARY_DIRS ${libdir} )
 209 set ( LIBFTDI_ROOT_DIR ${prefix} )
 210 set ( LIBFTDI_VERSION_STRING ${VERSION_STRING} )
 211 set ( LIBFTDI_VERSION_MAJOR ${MAJOR_VERSION} )
 212 set ( LIBFTDI_VERSION_MINOR ${MINOR_VERSION} )
 213
 214 set ( LIBFTDI_USE_FILE ${CMAKE_INSTALL_PREFIX}/${LIBFTDI_CMAKE_CONFIG_DIR}/UseLibFTDI1.cmake )
 215
 216 include(CMakePackageConfigHelpers)
 217
 218 configure_package_config_file (
 219   cmake/LibFTDI1Config.cmake.in
 220   ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake
 221   INSTALL_DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR}
 222   PATH_VARS
 223     LIBFTDI_USE_FILE
 224     LIBFTDI_ROOT_DIR
 225     LIBFTDI_INCLUDE_DIR
 226     LIBFTDI_INCLUDE_DIRS
 227     LIBFTDI_LIBRARY_DIRS
 228   NO_CHECK_REQUIRED_COMPONENTS_MACRO
 229 )
 230 write_basic_package_version_file (
 231   LibFTDI1ConfigVersion.cmake
 232   VERSION ${LIBFTDI_VERSION_STRING}
 233   COMPATIBILITY AnyNewerVersion
 234 )
 235
 236 install (
 237   FILES
 238     ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake
 239     ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1ConfigVersion.cmake
 240     cmake/UseLibFTDI1.cmake
 241   DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR}
 242 )
 243
 244 include(CPack)
 245
 246 message (STATUS "Summary of build options:
 247
 248   Build static libs: ${STATICLIBS}
 249   Build C++ bindings: ${FTDIPP}
 250   Build Python bindings: ${PYTHON_BINDINGS}
 251   Build ftdi_eeprom: ${FTDI_EEPROM}
 252   Build examples: ${EXAMPLES}
 253   Build tests: ${BUILD_TESTS}
 254   Build API documentation: ${DOCUMENTATION}
 255 ")