developer.intra2net.com Git - libftdi/blob - CMakeLists.txt

   1 # Project
   2 project(libftdi)
   3 set(MAJOR_VERSION 0)
   4 set(MINOR_VERSION 15)
   5 set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION})
   6 SET(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}")
   7
   8 # CMake
   9 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  10    set(CMAKE_BUILD_TYPE     Debug)
  11 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  12 set(CMAKE_COLOR_MAKEFILE ON)
  13 cmake_minimum_required(VERSION 2.6 FATAL_ERROR)
  14
  15 # Debug build
  16 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  17 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  18    add_definitions(-DDEBUG)
  19 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  20
  21 FIND_PACKAGE(USB REQUIRED)
  22 INCLUDE_DIRECTORIES(${LIBUSB_INCLUDE_DIR})
  23
  24 # Set components
  25 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  26 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  27 set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries")
  28 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  29
  30 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  31 "Shared library for general use.")
  32 set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION
  33 "Static library, good if you want to embed libftdi in your application.")
  34 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  35 "C/C++ header files.")
  36
  37 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  38 set(CPACK_COMPONENT_STATICLIBS_GROUP "Development")
  39 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  40
  41 # Package information
  42 set(CPACK_PACKAGE_VERSION              ${VERSION_STRING})
  43 set(CPACK_PACKAGE_CONTACT              "Marek Vavrusa <marek@vavrusa.com>")
  44 set(CPACK_PACKAGE_DESCRIPTION          "libftdi library.")
  45 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION}
  46                                        )
  47 # Package settings
  48 if(${UNIX})
  49   set(CPACK_GENERATOR                    "DEB;RPM")
  50   set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
  51   set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
  52   set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION})
  53 endif(${UNIX})
  54
  55 if(${WIN32})
  56   set(CPACK_GENERATOR                    "NSIS")
  57   set(CPACK_CMAKE_GENERATOR              "MinGW Makefiles")
  58   set(CPACK_PACKAGE_NAME                 "${PROJECT_NAME}")
  59   set(CPACK_PACKAGE_VENDOR               "")
  60   set(CPACK_PACKAGE_INSTALL_DIRECTORY    "libftdi")
  61   set(CPACK_PACKAGE_FILE_NAME            "${PROJECT_NAME}-${VERSION_STRING}-win32")
  62   set(CPACK_NSIS_DISPLAY_NAME            "libftdi")
  63   set(CPACK_NSIS_MODIFY_PATH             "ON")
  64 endif(${WIN32})
  65
  66 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/LICENSE)
  67
  68 set(CPACK_SOURCE_GENERATOR             TGZ)
  69 set(CPACK_SOURCE_IGNORE_FILES          "\\\\.git")
  70 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_FILE_NAME})
  71
  72 # Subdirectories
  73 if(${UNIX})
  74   set(CPACK_SET_DESTDIR "ON")
  75 endif(${UNIX})
  76
  77 add_subdirectory(src)
  78 add_subdirectory(ftdipp)
  79 add_subdirectory(examples)
  80 add_subdirectory(packages)
  81
  82
  83
  84 # Documentation
  85 find_package(Doxygen)
  86 if(DOXYGEN_FOUND)
  87
  88    # Set variables
  89    set(PACKAGE libftdi)
  90    set(VERSION ${VERSION_STRING})
  91    set(top_srcdir ${CMAKE_SOURCE_DIR})
  92
  93    # Find doxy config
  94    message(STATUS "Doxygen found.")
  95    set(DOXY_DIR "${CMAKE_SOURCE_DIR}/doc")
  96    set(DOXY_CONFIG "${DOXY_DIR}/Doxyfile.in")
  97
  98    # Copy doxy.config.in
  99    configure_file("${DOXY_CONFIG}" "${CMAKE_BINARY_DIR}/doxy.config")
 100
 101    # Create doc directory
 102    add_custom_command(
 103    OUTPUT ${CMAKE_BINARY_DIR}/doc
 104    COMMAND rm -rf ${CMAKE_BINARY_DIR}/doc
 105    COMMAND mkdir ${CMAKE_BINARY_DIR}/doc
 106    DEPENDS ftdi ftdipp
 107    )
 108
 109    # Run doxygen
 110    add_custom_command(
 111    OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html
 112    COMMAND ${DOXYGEN_EXECUTABLE} "${CMAKE_BINARY_DIR}/doxy.config"
 113    DEPENDS "${CMAKE_BINARY_DIR}/doxy.config" "${CMAKE_BINARY_DIR}/doc"
 114    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/doc
 115    )
 116
 117    add_custom_target(docs ALL DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html)
 118
 119 endif(DOXYGEN_FOUND)
 120
 121 # PkgConfig
 122 set(prefix      ${CMAKE_INSTALL_PREFIX})
 123 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 124 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 125
 126 if(${UNIX})
 127    set(libdir      ${CMAKE_INSTALL_PREFIX}/lib)
 128 endif(${UNIX})
 129 if(${WIN32})
 130    set(libdir      ${CMAKE_INSTALL_PREFIX}/bin)
 131 endif(${WIN32})
 132
 133 configure_file(${CMAKE_SOURCE_DIR}/libftdi.pc.in ${CMAKE_BINARY_DIR}/libftdi.pc @ONLY)
 134 configure_file(${CMAKE_SOURCE_DIR}/libftdipp.pc.in ${CMAKE_BINARY_DIR}/libftdipp.pc @ONLY)
 135 install(FILES ${CMAKE_BINARY_DIR}/libftdi.pc ${CMAKE_BINARY_DIR}/libftdipp.pc
 136         DESTINATION lib/pkgconfig)
 137
 138 if(${UNIX})
 139     configure_file(${CMAKE_SOURCE_DIR}/libftdi-config.in ${CMAKE_BINARY_DIR}/libftdi-config @ONLY)
 140     install(PROGRAMS ${CMAKE_BINARY_DIR}/libftdi-config DESTINATION bin)
 141 endif(${UNIX})
 142
 143 include(CPack)