developer.intra2net.com Git - libftdi/blob - CMakeLists.txt

   1 # Project
   2 project(libftdi)
   3 set(MAJOR_VERSION 0)
   4 set(MINOR_VERSION 17)
   5 set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION})
   6 SET(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}")
   7
   8 # CMake
   9 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  10    set(CMAKE_BUILD_TYPE     Debug)
  11 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  12 set(CMAKE_COLOR_MAKEFILE ON)
  13 cmake_minimum_required(VERSION 2.6 FATAL_ERROR)
  14
  15 # Debug build
  16 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  17 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  18    add_definitions(-DDEBUG)
  19 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  20
  21 FIND_PACKAGE(USB1 REQUIRED)
  22 INCLUDE_DIRECTORIES(${LIBUSB_INCLUDE_DIR})
  23
  24 # Find Boost (optional package)
  25 find_package(Boost)
  26
  27 # Set components
  28 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  29 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  30 set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries")
  31 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  32
  33 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  34 "Shared library for general use.")
  35 set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION
  36 "Static library, good if you want to embed libftdi in your application.")
  37 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  38 "C/C++ header files.")
  39
  40 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  41 set(CPACK_COMPONENT_STATICLIBS_GROUP "Development")
  42 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  43
  44 if(NOT APPLE)
  45   # Create suffix to eventually install in lib64
  46   if(CMAKE_SIZEOF_VOID_P EQUAL 4)
  47       SET(LIB_SUFFIX "")
  48       SET(PACK_ARCH "")
  49     else(CMAKE_SIZEOF_VOID_P EQUAL 8)
  50       SET(LIB_SUFFIX 64)
  51       SET(PACK_ARCH .x86_64)
  52   endif(CMAKE_SIZEOF_VOID_P EQUAL 4)
  53 else(NOT APPLE)
  54   SET(LIB_SUFFIX "")
  55   SET(PACK_ARCH "")
  56 endif(NOT APPLE)
  57
  58 # Package information
  59 set(CPACK_PACKAGE_VERSION              ${VERSION_STRING})
  60 set(CPACK_PACKAGE_CONTACT              "Marek Vavrusa <marek@vavrusa.com>")
  61 set(CPACK_PACKAGE_DESCRIPTION          "libftdi library.")
  62 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION}
  63                                        )
  64 # Package settings
  65 if(${UNIX})
  66   set(CPACK_GENERATOR                    "DEB;RPM")
  67   set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
  68   set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
  69   set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})
  70 endif(${UNIX})
  71
  72 if(${WIN32})
  73   set(CPACK_GENERATOR                    "NSIS")
  74   set(CPACK_CMAKE_GENERATOR              "MinGW Makefiles")
  75   set(CPACK_PACKAGE_NAME                 "${PROJECT_NAME}")
  76   set(CPACK_PACKAGE_VENDOR               "")
  77   set(CPACK_PACKAGE_INSTALL_DIRECTORY    "libftdi")
  78   set(CPACK_PACKAGE_FILE_NAME            "${PROJECT_NAME}-${VERSION_STRING}-win32")
  79   set(CPACK_NSIS_DISPLAY_NAME            "libftdi")
  80   set(CPACK_NSIS_MODIFY_PATH             "ON")
  81 endif(${WIN32})
  82
  83 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/LICENSE)
  84
  85 set(CPACK_SOURCE_GENERATOR             TGZ)
  86 set(CPACK_SOURCE_IGNORE_FILES          "\\\\.git")
  87 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_FILE_NAME})
  88
  89 # Subdirectories
  90 if(${UNIX})
  91   set(CPACK_SET_DESTDIR "ON")
  92 endif(${UNIX})
  93
  94 add_subdirectory(src)
  95 add_subdirectory(ftdipp)
  96 add_subdirectory(bindings)
  97 add_subdirectory(examples)
  98 add_subdirectory(packages)
  99
 100
 101
 102 # Documentation
 103
 104 option(DOCUMENTATION "Generate API documentation with Doxygen" ON)
 105
 106 find_package(Doxygen)
 107 if(DOCUMENTATION AND DOXYGEN_FOUND)
 108
 109    # Set variables
 110    set(PACKAGE libftdi)
 111    set(VERSION ${VERSION_STRING})
 112    set(top_srcdir ${CMAKE_SOURCE_DIR})
 113
 114    # Find doxy config
 115    message(STATUS "Doxygen found.")
 116    set(DOXY_DIR "${CMAKE_SOURCE_DIR}/doc")
 117    set(DOXY_CONFIG "${DOXY_DIR}/Doxyfile.in")
 118
 119    # Copy doxy.config.in
 120    configure_file("${DOXY_CONFIG}" "${CMAKE_BINARY_DIR}/doxy.config")
 121
 122    # Create doc directory
 123    add_custom_command(
 124    OUTPUT ${CMAKE_BINARY_DIR}/doc
 125    COMMAND rm -rf ${CMAKE_BINARY_DIR}/doc
 126    COMMAND mkdir ${CMAKE_BINARY_DIR}/doc
 127    DEPENDS ftdi ftdipp
 128    )
 129
 130    # Run doxygen
 131    add_custom_command(
 132    OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html
 133    COMMAND ${DOXYGEN_EXECUTABLE} "${CMAKE_BINARY_DIR}/doxy.config"
 134    DEPENDS "${CMAKE_BINARY_DIR}/doxy.config" "${CMAKE_BINARY_DIR}/doc"
 135    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/doc
 136    )
 137
 138    add_custom_target(docs ALL DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html)
 139
 140    message(STATUS "Generating API documentation with Doxygen")
 141 else(DOCUMENTATION AND DOXYGEN_FOUND)
 142    message(STATUS "Not generating API documentation")
 143 endif(DOCUMENTATION AND DOXYGEN_FOUND)
 144
 145 # PkgConfig
 146 set(prefix      ${CMAKE_INSTALL_PREFIX})
 147 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 148 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 149
 150 if(${UNIX})
 151    set(libdir      ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
 152 endif(${UNIX})
 153 if(${WIN32})
 154    set(libdir      ${CMAKE_INSTALL_PREFIX}/bin)
 155 endif(${WIN32})
 156
 157 configure_file(${CMAKE_SOURCE_DIR}/libftdi.pc.in ${CMAKE_BINARY_DIR}/libftdi.pc @ONLY)
 158 configure_file(${CMAKE_SOURCE_DIR}/libftdipp.pc.in ${CMAKE_BINARY_DIR}/libftdipp.pc @ONLY)
 159 install(FILES ${CMAKE_BINARY_DIR}/libftdi.pc ${CMAKE_BINARY_DIR}/libftdipp.pc
 160         DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 161
 162 if(${UNIX})
 163     configure_file(${CMAKE_SOURCE_DIR}/libftdi-config.in ${CMAKE_BINARY_DIR}/libftdi-config @ONLY)
 164     install(PROGRAMS ${CMAKE_BINARY_DIR}/libftdi-config DESTINATION bin)
 165 endif(${UNIX})
 166
 167 include(CPack)