developer.intra2net.com Git - libftdi/blob - CMakeLists.txt

   1 # Project
   2 project(libftdi1)
   3 set(MAJOR_VERSION 1)
   4 set(MINOR_VERSION 0)
   5 set(PACKAGE libftdi1)
   6 set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION})
   7 set(VERSION ${VERSION_STRING})
   8 set ( CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake )
   9
  10 # CMake
  11 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  12    set(CMAKE_BUILD_TYPE     RelWithDebInfo)
  13 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  14 set(CMAKE_COLOR_MAKEFILE ON)
  15 cmake_minimum_required(VERSION 2.6 FATAL_ERROR)
  16
  17 add_definitions(-Wall)
  18
  19 # Debug build
  20 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  21 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  22    add_definitions(-DDEBUG)
  23 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  24
  25 # find libusb
  26 find_package ( USB1 REQUIRED )
  27 include_directories ( ${LIBUSB_INCLUDE_DIR} )
  28
  29 # Find Boost (optional package)
  30 find_package(Boost)
  31
  32 # Set components
  33 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  34 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  35 set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries")
  36 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  37
  38 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  39 "Shared library for general use.")
  40 set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION
  41 "Static library, good if you want to embed libftdi1 in your application.")
  42 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  43 "C/C++ header files.")
  44
  45 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  46 set(CPACK_COMPONENT_STATICLIBS_GROUP "Development")
  47 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  48
  49 # guess LIB_SUFFIX, don't take debian multiarch into account
  50 if ( NOT DEFINED LIB_SUFFIX )
  51   if ( CMAKE_SYSTEM_NAME MATCHES "Linux" AND NOT CMAKE_CROSSCOMPILING AND NOT EXISTS "/etc/debian_version" )
  52     if ( "${CMAKE_SIZEOF_VOID_P}" EQUAL "8" )
  53       set ( LIB_SUFFIX 64 )
  54     endif ()
  55   endif ()
  56 endif ()
  57
  58 if(NOT APPLE)
  59   if(CMAKE_SIZEOF_VOID_P EQUAL 4)
  60       SET(PACK_ARCH "")
  61     else(CMAKE_SIZEOF_VOID_P EQUAL 8)
  62       SET(PACK_ARCH .x86_64)
  63   endif(CMAKE_SIZEOF_VOID_P EQUAL 4)
  64 else(NOT APPLE)
  65   SET(PACK_ARCH "")
  66 endif(NOT APPLE)
  67
  68 # Package information
  69 set(CPACK_PACKAGE_VERSION              ${VERSION_STRING})
  70 set(CPACK_PACKAGE_CONTACT              "Intra2net AG <libftdi@developer.intra2net.com>")
  71 set(CPACK_PACKAGE_DESCRIPTION          "libftdi1 library.")
  72 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION}
  73                                        )
  74 # Package settings
  75 if ( UNIX )
  76   set(CPACK_GENERATOR                    "DEB;RPM")
  77   set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
  78   set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
  79   set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})
  80 endif ()
  81
  82 if ( WIN32 )
  83   set ( CPACK_GENERATOR                    "NSIS" )
  84   set ( CPACK_CMAKE_GENERATOR              "MinGW Makefiles" )
  85   set ( CPACK_PACKAGE_NAME                 "${PROJECT_NAME}" )
  86   set ( CPACK_PACKAGE_VENDOR               "" )
  87   set ( CPACK_PACKAGE_INSTALL_DIRECTORY    "libftdi1" )
  88   set ( CPACK_PACKAGE_FILE_NAME            "${PROJECT_NAME}-${VERSION_STRING}-win32")
  89   set ( CPACK_NSIS_DISPLAY_NAME            "libftdi1" )
  90   set ( CPACK_NSIS_MODIFY_PATH             ON )
  91 endif ()
  92
  93 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/LICENSE)
  94
  95 set(CPACK_SOURCE_GENERATOR             TGZ)
  96 set(CPACK_SOURCE_IGNORE_FILES          "\\\\.git;~$;build/")
  97 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION})
  98
  99 # Subdirectories
 100 if ( UNIX )
 101   set ( CPACK_SET_DESTDIR ON )
 102 endif ()
 103
 104 # "make dist" target
 105 set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION_STRING})
 106 add_custom_target(dist
 107     COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
 108             | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
 109     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 110
 111
 112 # Documentation
 113 option ( DOCUMENTATION "Generate API documentation with Doxygen" ON )
 114
 115
 116 find_package ( Doxygen )
 117 if ( DOCUMENTATION AND DOXYGEN_FOUND )
 118
 119    # Find doxy config
 120    message(STATUS "Doxygen found.")
 121
 122    # Copy doxy.config.in
 123    set(top_srcdir ${CMAKE_SOURCE_DIR})
 124    configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.in ${CMAKE_BINARY_DIR}/Doxyfile )
 125    configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.xml.in ${CMAKE_BINARY_DIR}/Doxyfile.xml )
 126
 127    # Run doxygen
 128    add_custom_command(
 129     OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html
 130     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc
 131     COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile
 132     DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers}
 133    )
 134
 135    add_custom_target(docs ALL DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html)
 136
 137    message(STATUS "Generating API documentation with Doxygen")
 138 else(DOCUMENTATION AND DOXYGEN_FOUND)
 139    message(STATUS "Not generating API documentation")
 140 endif(DOCUMENTATION AND DOXYGEN_FOUND)
 141
 142 add_subdirectory(src)
 143 add_subdirectory(ftdipp)
 144 add_subdirectory(python)
 145 add_subdirectory(ftdi_eeprom)
 146 add_subdirectory(examples)
 147 add_subdirectory(packages)
 148 add_subdirectory(test)
 149
 150 # PkgConfig
 151 set(prefix      ${CMAKE_INSTALL_PREFIX})
 152 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 153 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 154
 155 if(${UNIX})
 156    set(libdir      ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
 157 endif(${UNIX})
 158 if(${WIN32})
 159    set(libdir      ${CMAKE_INSTALL_PREFIX}/bin)
 160 endif(${WIN32})
 161
 162 configure_file(${CMAKE_SOURCE_DIR}/libftdi1.spec.in ${CMAKE_BINARY_DIR}/libftdi1.spec @ONLY)
 163 configure_file(${CMAKE_SOURCE_DIR}/libftdi1.pc.in ${CMAKE_BINARY_DIR}/libftdi1.pc @ONLY)
 164 configure_file(${CMAKE_SOURCE_DIR}/libftdipp1.pc.in ${CMAKE_BINARY_DIR}/libftdipp1.pc @ONLY)
 165 install(FILES ${CMAKE_BINARY_DIR}/libftdi1.pc ${CMAKE_BINARY_DIR}/libftdipp1.pc
 166         DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 167
 168 if ( UNIX )
 169   configure_file ( libftdi1-config.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config @ONLY )
 170   install ( PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config
 171             DESTINATION bin )
 172
 173   # config script install path
 174   if ( NOT DEFINED LIBFTDI_CMAKE_CONFIG_DIR )
 175     set ( LIBFTDI_CMAKE_CONFIG_DIR lib${LIB_SUFFIX}/cmake/libftdi1 )
 176   endif ()
 177
 178   set ( LIBFTDI_INCLUDE_DIR ${includedir} )
 179   set ( LIBFTDI_INCLUDE_DIRS ${LIBFTDI_INCLUDE_DIR} )
 180   get_target_property( _LIBFTDI_LIBRARY_LOCATION ftdi1 LOCATION )
 181   get_filename_component ( _LIBFTDI_LIBRARY_NAME ${_LIBFTDI_LIBRARY_LOCATION} NAME )
 182   set ( LIBFTDI_LIBRARY ${libdir}/${_LIBFTDI_LIBRARY_NAME} )
 183   set ( LIBFTDI_LIBRARIES ${LIBFTDI_LIBRARY} )
 184   list ( APPEND LIBFTDI_LIBRARIES ${LIBUSB_LIBRARIES} )
 185   get_target_property( _LIBFTDIPP_LIBRARY_LOCATION ftdipp1 LOCATION )
 186   get_filename_component ( _LIBFTDIPP_LIBRARY_NAME ${_LIBFTDIPP_LIBRARY_LOCATION} NAME )
 187   set ( LIBFTDIPP_LIBRARY ${libdir}/${_LIBFTDIPP_LIBRARY_NAME} )
 188   set ( LIBFTDIPP_LIBRARIES ${LIBFTDIPP_LIBRARY} )
 189   list ( APPEND LIBFTDIPP_LIBRARIES ${LIBUSB_LIBRARIES} )
 190   set ( LIBFTDI_ROOT_DIR ${prefix} )
 191   set ( LIBFTDI_VERSION_STRING ${VERSION_STRING} )
 192   set ( LIBFTDI_VERSION_MAJOR ${MAJOR_VERSION} )
 193   set ( LIBFTDI_VERSION_MINOR ${MINOR_VERSION} )
 194
 195   set ( LIBFTDI_USE_FILE ${CMAKE_INSTALL_PREFIX}/${LIBFTDI_CMAKE_CONFIG_DIR}/UseLibFTDI1.cmake )
 196   configure_file ( LibFTDI1Config.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake @ONLY )
 197   install ( FILES ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake UseLibFTDI1.cmake
 198             DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR}
 199           )
 200 endif ()
 201
 202 include(CPack)