developer.intra2net.com Git - libftdi/blob - python/CMakeLists.txt

   1 # swig_add_library behavior changed in cmake 3.13 to no longer set
   2 # SWIG_MODULE_<target>_REAL_NAME, so restore the old behavior.
   3 if ( POLICY CMP0078 )
   4   cmake_policy( SET CMP0078 OLD )
   5 endif ()
   6
   7 # workaround for cmake bug #0013449
   8 if ( NOT DEFINED CMAKE_FIND_ROOT_PATH OR NOT CMAKE_VERSION VERSION_LESS 3.0.0 )
   9   find_package ( SWIG REQUIRED )
  10 else ()
  11   find_program ( SWIG_EXECUTABLE NAMES swig2.0 swig )
  12   if ( SWIG_EXECUTABLE )
  13     set ( SWIG_USE_FILE ${CMAKE_ROOT}/Modules/UseSWIG.cmake )
  14     set ( SWIG_FOUND TRUE )
  15   endif ()
  16 endif ()
  17 find_package ( PythonLibs REQUIRED )
  18 find_package ( PythonInterp REQUIRED )
  19
  20 include ( UseSWIG )
  21 include_directories ( BEFORE ${CMAKE_SOURCE_DIR}/src )
  22 include_directories ( ${PYTHON_INCLUDE_DIRS} )
  23 link_directories ( ${CMAKE_CURRENT_BINARY_DIR}/../src )
  24
  25 if ( DOCUMENTATION )
  26   set(CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
  27   # manually add dependency for new cmake / swig versions
  28   set_property(SOURCE ftdi1.i PROPERTY DEPENDS ftdi1_doc.i)
  29 endif()
  30 if(NOT CMAKE_VERSION VERSION_LESS 3.8.0)
  31   swig_add_library ( ftdi1 LANGUAGE python SOURCES ftdi1.i )
  32 else ()
  33   swig_add_module ( ftdi1 python ftdi1.i )
  34 endif()
  35 swig_link_libraries ( ftdi1 ftdi1 )
  36
  37 if ( LINK_PYTHON_LIBRARY )
  38   swig_link_libraries ( ftdi1 ${PYTHON_LIBRARIES} )
  39 elseif( APPLE )
  40   set_target_properties ( ${SWIG_MODULE_ftdi1_REAL_NAME} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup" )
  41 endif ()
  42
  43 set_target_properties ( ${SWIG_MODULE_ftdi1_REAL_NAME} PROPERTIES NO_SONAME ON )
  44
  45 execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; print( sysconfig.get_python_lib( plat_specific=True, prefix='${CMAKE_INSTALL_PREFIX}' ) )"
  46                   OUTPUT_VARIABLE _ABS_PYTHON_MODULE_PATH
  47                   OUTPUT_STRIP_TRAILING_WHITESPACE )
  48
  49 get_filename_component ( _ABS_PYTHON_MODULE_PATH ${_ABS_PYTHON_MODULE_PATH} ABSOLUTE )
  50 file ( RELATIVE_PATH _REL_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX} ${_ABS_PYTHON_MODULE_PATH} )
  51
  52 set ( PYTHON_MODULE_PATH ${_REL_PYTHON_MODULE_PATH} )
  53
  54 install ( FILES ${CMAKE_CURRENT_BINARY_DIR}/ftdi1.py DESTINATION ${PYTHON_MODULE_PATH} )
  55 install ( TARGETS ${SWIG_MODULE_ftdi1_REAL_NAME} LIBRARY DESTINATION ${PYTHON_MODULE_PATH} )
  56
  57 if ( DOCUMENTATION )
  58     # Run doxygen to only generate the xml
  59     add_custom_command ( OUTPUT ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  60         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc
  61         COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile.xml
  62         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  63         DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers}
  64     )
  65
  66     # generate .i from doxygen .xml
  67     add_custom_command ( OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  68         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
  69             ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  70             ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  71         DEPENDS ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  72     )
  73     add_custom_target ( doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i )
  74     add_dependencies( ${SWIG_MODULE_ftdi1_REAL_NAME} doc_i )
  75
  76 endif ()
  77
  78 set ( LIBFTDI_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX}/${PYTHON_MODULE_PATH} )
  79 set ( LIBFTDI_PYTHON_MODULE_PATH ${LIBFTDI_PYTHON_MODULE_PATH} PARENT_SCOPE ) # for ftdiconfig.cmake
  80
  81 add_subdirectory ( examples )