developer.intra2net.com Git - libftdi/blob - python/CMakeLists.txt

   1 option ( PYTHON_BINDINGS "Build python bindings via swig" ON )
   2
   3 if ( PYTHON_BINDINGS )
   4   find_package ( SWIG )
   5   find_package ( PythonLibs )
   6   find_package ( PythonInterp )
   7 endif ()
   8
   9 if ( SWIG_FOUND AND PYTHONLIBS_FOUND AND PYTHONINTERP_FOUND )
  10   include ( UseSWIG )
  11   include_directories ( BEFORE ${CMAKE_SOURCE_DIR}/src )
  12   include_directories ( ${PYTHON_INCLUDE_DIRS} )
  13   link_directories ( ${CMAKE_CURRENT_BINARY_DIR}/../src )
  14
  15   swig_add_module ( ftdi1 python ftdi1.i )
  16   swig_link_libraries ( ftdi1 ftdi1 )
  17
  18   # do not link python modules on debian
  19   # http://www.debian.org/doc/packaging-manuals/python-policy/ch-module_packages.html
  20   if ( NOT UNIX OR ( UNIX AND NOT EXISTS "/etc/debian_version" ) )
  21     swig_link_libraries ( ftdi1 ${PYTHON_LIBRARIES} )
  22   endif ()
  23
  24   execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; print( sysconfig.get_python_lib( plat_specific=True, prefix='${CMAKE_INSTALL_PREFIX}' ) )"
  25                     OUTPUT_VARIABLE _ABS_PYTHON_MODULE_PATH
  26                     OUTPUT_STRIP_TRAILING_WHITESPACE )
  27
  28   get_filename_component ( _ABS_PYTHON_MODULE_PATH ${_ABS_PYTHON_MODULE_PATH} ABSOLUTE )
  29   file ( RELATIVE_PATH _REL_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX} ${_ABS_PYTHON_MODULE_PATH} )
  30
  31   set ( PYTHON_MODULE_PATH
  32         ${_REL_PYTHON_MODULE_PATH}
  33       )
  34
  35   INSTALL ( FILES ${CMAKE_CURRENT_BINARY_DIR}/_ftdi1.so DESTINATION ${PYTHON_MODULE_PATH} )
  36   INSTALL ( FILES ${CMAKE_CURRENT_BINARY_DIR}/ftdi1.py DESTINATION ${PYTHON_MODULE_PATH} )
  37
  38   if ( DOCUMENTATION AND DOXYGEN_FOUND )
  39
  40       set(CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
  41
  42       # Run doxygen to only generate the xml
  43       add_custom_command ( OUTPUT ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  44           COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc
  45           COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile.xml
  46           WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  47           DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers}
  48       )
  49
  50       # generate .i from doxygen .xml
  51       add_custom_command ( OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  52           COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
  53               ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  54               ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  55           DEPENDS ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  56       )
  57       add_custom_target ( doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i )
  58       add_dependencies( ${SWIG_MODULE_ftdi1_REAL_NAME} doc_i )
  59
  60   endif ()
  61
  62   set ( LIBFTDI_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX}/${PYTHON_MODULE_PATH} )
  63   set ( LIBFTDI_PYTHON_MODULE_PATH ${LIBFTDI_PYTHON_MODULE_PATH} PARENT_SCOPE ) # for ftdiconfig.cmake
  64   message(STATUS "Building python bindings via swig. Will be installed under ${LIBFTDI_PYTHON_MODULE_PATH}")
  65
  66   add_subdirectory ( examples )
  67 else ()
  68   message(STATUS "Not building python bindings")
  69 endif ()