developer.intra2net.com Git - libftdi/blob - configure.in

   1 AC_INIT(libftdi, 0.17)
   2 AM_INIT_AUTOMAKE
   3 AM_CONFIG_HEADER(config.h)
   4
   5 AC_LANG_C
   6 AC_PROG_CC
   7 AM_PROG_LIBTOOL
   8 AC_PROG_CXX
   9
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 dnl check for libusb-1.0
  13 have_libusb_1_0=no
  14 PKG_CHECK_MODULES(LIBUSB_1_0, [ libusb-1.0 >= 1.0.0 ], have_libusb_1_0=yes, have_libusb_1_0=no)
  15 if test "$have_libusb_1_0" = "yes"; then
  16   CFLAGS="$CFLAGS $LIBUSB_1_0_CFLAGS"
  17   CXXFLAGS="$CXXFLAGS $LIBUSB_1_0_CFLAGS"
  18   USB_LIBS="$USB_LIBS $LIBUSB_1_0_LIBS"
  19   HAVE_USB=yes
  20   AC_DEFINE(HAVE_LIBUSB_1_0, 1, [Define to 1 if you have libusb-1.0.])
  21   AC_SUBST(USB_LIBS)
  22 else
  23   AC_MSG_ERROR([libusb-1.0 not found.])
  24 fi
  25
  26 ENABLE_ASYNC_MODE=0
  27 AC_ARG_WITH(async-mode,
  28 [  --with-async-mode       enable experimental async mode. Linux only.],
  29 [
  30   AC_MSG_CHECKING(for experimental linux async mode)
  31   if test "$withval" != "no"; then
  32     ENABLE_ASYNC_MODE=1
  33     CFLAGS="$CFLAGS -DLIBFTDI_LINUX_ASYNC_MODE"
  34     AC_MSG_RESULT(yes)
  35   else
  36     AC_MSG_RESULT(no)
  37   fi
  38 ])
  39 AC_SUBST(ENABLE_ASYNC_MODE)
  40
  41 LIBFTDI_MODULES=
  42 LIBFTDI_MODULES_PKGCONFIG=
  43
  44 dnl libftdi C++ wrapper. Needs boost.
  45 AX_BOOST_BASE([1.33])
  46 ENABLE_LIBFTDIPP=0
  47 AC_MSG_CHECKING(if we can build the C++ wrapper)
  48 AC_ARG_ENABLE(libftdipp,
  49                           AS_HELP_STRING([--enable-libftdipp],
  50                                                      [enable libftdi C++ wrapper. Needs boost (default: auto)]),
  51 [
  52     if test "$enableval" != "no"; then
  53         if test "x$HAVE_BOOST" != "xyes"; then
  54             AC_MSG_ERROR(Sorry, we need the boost library for the C++ wrapper)
  55         fi
  56         ENABLE_LIBFTDIPP=1
  57     fi
  58 ],
  59 [
  60     dnl Build the wrapper if we got the boost library
  61     if test "x$HAVE_BOOST" = "xyes"; then
  62         ENABLE_LIBFTDIPP=1
  63     fi
  64 ])
  65 if test "x$ENABLE_LIBFTDIPP" = "x1"; then
  66     LIBFTDI_MODULES="$LIBFTDI_MODULES ftdipp"
  67     LIBFTDI_MODULES_PKGCONFIG="$LIBFTDI_MODULES_PKGCONFIG libftdipp.pc"
  68     AC_MSG_RESULT(yes)
  69 else
  70     AC_MSG_RESULT(no)
  71 fi
  72 AM_CONDITIONAL(HAVE_LIBFTDIPP, [test "x$ENABLE_LIBFTDIPP" = "x1"])
  73
  74 dnl check for doxygen
  75 AC_PATH_PROG(DOXYGEN, doxygen)
  76 AM_CONDITIONAL(HAVE_DOXYGEN, test -n $DOXYGEN)
  77
  78 dnl ============================
  79 dnl Bindings for other languages
  80 dnl ==
  81
  82 dnl ===============
  83 dnl Checks for SWIG
  84 dnl ===============
  85 AC_PATH_PROG([SWIG], [swig])
  86 AM_CONDITIONAL(HAVE_SWIG, test "$SWIG")
  87
  88 dnl =================
  89 dnl Checks for Python
  90 dnl =================
  91 AM_PATH_PYTHON([2.0],
  92                [],
  93                [AC_MSG_WARN([Python not found. Python is required to build presage python binding. Python can be obtained from http://www.pyth
  94 on.org])])
  95 if test "$PYTHON"
  96 then
  97      python_include_path=`$PYTHON -c "import distutils.sysconfig; print distutils.sysconfig.get_python_inc();"`
  98      AC_CHECK_HEADERS([${python_include_path}/Python.h],
  99                       [have_python_header=true],
 100                       [AC_MSG_WARN([Python.h header file not found. Python development files are required to build presage python binding. Pyt
 101 hon can be obtained from http://www.python.org])],
 102                       [])
 103 fi
 104 AM_CONDITIONAL(HAVE_PYTHON, test "$PYTHON" -a "x$have_python_header" = "xtrue")
 105
 106 AC_ARG_ENABLE([python-binding],
 107                AS_HELP_STRING([--enable-python-binding],
 108                               [build python binding (default=no)]),
 109                [ac_enable_python_binding=$enableval],
 110                [ac_enable_python_binding=no])
 111 if test "x$ac_enable_python_binding" = "xyes"
 112 then
 113     if test ! "$SWIG" -o ! "$PYTHON" -o ! "x$have_python_header" = "xtrue"
 114     then
 115         AC_MSG_WARN([Python binding for libftdi cannot be built. Ensure that SWIG and Python packages are available.])
 116     fi
 117 else
 118     AC_MSG_NOTICE([Python binding for libftdi will not be built.])
 119     AC_MSG_NOTICE([Enable Python binding module building with --enable-python-binding])
 120 fi
 121 AM_CONDITIONAL(ENABLE_PYTHON_BINDING, test "x$ac_enable_python_binding" = "xyes")
 122
 123 if test "$SWIG" -a "$PYTHON" -a "x$have_python_header" = "xtrue" -a "x$ac_enable_python_binding" = "xyes"
 124 then
 125     AC_MSG_NOTICE([Python binding for libftdi will be built.])
 126     build_python_binding="yes"
 127 else
 128     build_python_binding="no"
 129 fi
 130
 131 AC_SUBST(LIBFTDI_MODULES)
 132 AC_SUBST(LIBFTDI_MODULES_PKGCONFIG)
 133
 134 AC_CONFIG_FILES([libftdi-config],[chmod a+x libftdi-config])
 135 AC_CONFIG_FILES(Makefile src/Makefile bindings/Makefile bindings/python/Makefile bindings/python/setup.py examples/Makefile doc/Doxyfile doc/Makefile libftdi.pc libftdi.spec)
 136
 137 if test "x$ENABLE_LIBFTDIPP" = "x1"; then
 138     AC_CONFIG_FILES(ftdipp/Makefile libftdipp.pc)
 139 fi
 140
 141 AC_OUTPUT