developer.intra2net.com Git - libftdi/blob - configure.in

   1 AC_INIT(libftdi, 0.17)
   2 AM_INIT_AUTOMAKE
   3 AM_CONFIG_HEADER(config.h)
   4
   5 AC_LANG_C
   6 AC_PROG_CC
   7 AM_PROG_LIBTOOL
   8 AC_PROG_CXX
   9
  10 dnl check for libusb-config
  11 AC_PATH_PROG(HAVELIBUSB, libusb-config, $PATH)
  12
  13 if test ! -z "$HAVELIBUSB"; then
  14    LIBUSB_CFLAGS=`$HAVELIBUSB --cflags`
  15    LIBUSB_LIBS=`$HAVELIBUSB --libs`
  16
  17    CFLAGS="$CFLAGS $LIBUSB_CFLAGS"
  18    LIBS="$LIBS $LIBUSB_LIBS"
  19 else
  20    AC_MSG_ERROR([*** libusb-config not found. You need a working libusb installation.])
  21 fi
  22
  23 dnl check for version of libusb
  24 AC_MSG_CHECKING([if libusb version is >= 0.1.7])
  25 libusb_version_needed="1007"
  26 libusb_version=`$HAVELIBUSB --version | sed -e "s/libusb //" | awk 'BEGIN { FS = "."; } { printf "%d", ($''1 * 1000 + $''2) * 1000 + $''3;}'`
  27
  28 if test $libusb_version -lt $libusb_version_needed; then
  29    AC_MSG_RESULT(no)
  30    AC_MSG_ERROR([*** libusb is too old ($libusb_version). You need a libusb installation newer or equal to 0.1.7.])
  31 else
  32    AC_MSG_RESULT(yes)
  33 fi
  34
  35 ENABLE_ASYNC_MODE=0
  36 AC_ARG_WITH(async-mode,
  37 [  --with-async-mode       enable experimental async mode. Linux only.],
  38 [
  39   AC_MSG_CHECKING(for experimental linux async mode)
  40   if test "$withval" != "no"; then
  41     ENABLE_ASYNC_MODE=1
  42     CFLAGS="$CFLAGS -DLIBFTDI_LINUX_ASYNC_MODE"
  43     AC_MSG_RESULT(yes)
  44   else
  45     AC_MSG_RESULT(no)
  46   fi
  47 ])
  48 AC_SUBST(ENABLE_ASYNC_MODE)
  49
  50 LIBFTDI_MODULES=
  51 LIBFTDI_MODULES_PKGCONFIG=
  52
  53 dnl libftdi C++ wrapper. Needs boost.
  54 AX_BOOST_BASE([1.33])
  55 ENABLE_LIBFTDIPP=0
  56 AC_MSG_CHECKING(if we can build the C++ wrapper)
  57 AC_ARG_ENABLE(libftdipp,
  58                           AS_HELP_STRING([--enable-libftdipp],
  59                                                      [enable libftdi C++ wrapper. Needs boost (default: auto)]),
  60 [
  61     if test "$enableval" != "no"; then
  62         if test "x$HAVE_BOOST" != "xyes"; then
  63             AC_MSG_ERROR(Sorry, we need the boost library for the C++ wrapper)
  64         fi
  65         ENABLE_LIBFTDIPP=1
  66     fi
  67 ],
  68 [
  69     dnl Build the wrapper if we got the boost library
  70     if test "x$HAVE_BOOST" = "xyes"; then
  71         ENABLE_LIBFTDIPP=1
  72     fi
  73 ])
  74 if test "x$ENABLE_LIBFTDIPP" = "x1"; then
  75     LIBFTDI_MODULES="$LIBFTDI_MODULES ftdipp"
  76     LIBFTDI_MODULES_PKGCONFIG="$LIBFTDI_MODULES_PKGCONFIG libftdipp.pc"
  77     AC_MSG_RESULT(yes)
  78 else
  79     AC_MSG_RESULT(no)
  80 fi
  81 AM_CONDITIONAL(HAVE_LIBFTDIPP, [test "x$ENABLE_LIBFTDIPP" = "x1"])
  82
  83 dnl check for doxygen
  84 AC_PATH_PROG(DOXYGEN, doxygen)
  85 AM_CONDITIONAL(HAVE_DOXYGEN, test -n $DOXYGEN)
  86
  87 dnl ============================
  88 dnl Bindings for other languages
  89 dnl ==
  90
  91 dnl ===============
  92 dnl Checks for SWIG
  93 dnl ===============
  94 AC_PATH_PROG([SWIG], [swig])
  95 AM_CONDITIONAL(HAVE_SWIG, test "$SWIG")
  96
  97 dnl =================
  98 dnl Checks for Python
  99 dnl =================
 100 AM_PATH_PYTHON([2.0],
 101                [],
 102                [AC_MSG_WARN([Python not found. Python is required to build presage python binding. Python can be obtained from http://www.pyth
 103 on.org])])
 104 if test "$PYTHON"
 105 then
 106      python_include_path=`$PYTHON -c "import distutils.sysconfig; print distutils.sysconfig.get_python_inc();"`
 107      AC_CHECK_HEADERS([${python_include_path}/Python.h],
 108                       [have_python_header=true],
 109                       [AC_MSG_WARN([Python.h header file not found. Python development files are required to build presage python binding. Pyt
 110 hon can be obtained from http://www.python.org])],
 111                       [])
 112 fi
 113 AM_CONDITIONAL(HAVE_PYTHON, test "$PYTHON" -a "x$have_python_header" = "xtrue")
 114
 115 AC_ARG_ENABLE([python-binding],
 116                AS_HELP_STRING([--enable-python-binding],
 117                               [build python binding (default=no)]),
 118                [ac_enable_python_binding=$enableval],
 119                [ac_enable_python_binding=no])
 120 if test "x$ac_enable_python_binding" = "xyes"
 121 then
 122     if test ! "$SWIG" -o ! "$PYTHON" -o ! "x$have_python_header" = "xtrue"
 123     then
 124         AC_MSG_WARN([Python binding for libftdi cannot be built. Ensure that SWIG and Python packages are available.])
 125     fi
 126 else
 127     AC_MSG_NOTICE([Python binding for libftdi will not be built.])
 128     AC_MSG_NOTICE([Enable Python binding module building with --enable-python-binding])
 129 fi
 130 AM_CONDITIONAL(ENABLE_PYTHON_BINDING, test "x$ac_enable_python_binding" = "xyes")
 131
 132 if test "$SWIG" -a "$PYTHON" -a "x$have_python_header" = "xtrue" -a "x$ac_enable_python_binding" = "xyes"
 133 then
 134     AC_MSG_NOTICE([Python binding for libftdi will be built.])
 135     build_python_binding="yes"
 136 else
 137     build_python_binding="no"
 138 fi
 139
 140 AC_SUBST(LIBFTDI_MODULES)
 141 AC_SUBST(LIBFTDI_MODULES_PKGCONFIG)
 142
 143 AC_CONFIG_FILES([libftdi-config],[chmod a+x libftdi-config])
 144 AC_CONFIG_FILES(Makefile src/Makefile bindings/Makefile bindings/python/Makefile bindings/python/setup.py examples/Makefile doc/Doxyfile doc/Makefile libftdi.pc libftdi.spec)
 145
 146 if test "x$ENABLE_LIBFTDIPP" = "x1"; then
 147     AC_CONFIG_FILES(ftdipp/Makefile libftdipp.pc)
 148 fi
 149
 150 AC_OUTPUT