developer.intra2net.com Git - libt2n/blob - codegen/Libt2n.cmake

   1 # Version of this file: 1.3
   2
   3 # Detect libt2n
   4 pkg_check_modules(LIBT2N REQUIRED libt2n)
   5 include_directories(${LIBT2N_INCLUDE_DIRS})
   6 link_directories(${LIBT2N_LIBRARY_DIRS})
   7
   8 # Detect the boost serialization library
   9 find_package(Boost 1.34 COMPONENTS serialization REQUIRED)
  10 include_directories(${Boost_INCLUDE_DIRS})
  11
  12 # Get locations from pkgconfig
  13 execute_process(COMMAND ${PKG_CONFIG_EXECUTABLE} --variable libt2n_codegen libt2n
  14                                 OUTPUT_VARIABLE LIBT2N_CODEGEN
  15                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  16 execute_process(COMMAND ${PKG_CONFIG_EXECUTABLE} --variable libt2n_datadir libt2n
  17                                 OUTPUT_VARIABLE LIBT2N_DATADIR
  18                                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  19 set(LIBT2N_CLIENT_PCTEMPLATE ${LIBT2N_DATADIR}/clientlib.pc.in)
  20 set(LIBT2N_GCCXML /usr/bin/libt2n-gccxml.sh)
  21
  22 # Basic pkgconfig settings needed for client.pc generation
  23 set(prefix      ${CMAKE_INSTALL_PREFIX})
  24 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
  25 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
  26 set(libdir      ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
  27
  28 # Setup libt2n. Arguments are the CMDGROUP names
  29 function(setup_libt2n)
  30     string(LENGTH "${ARGV}" CMDGROUP_LEN)
  31     if (${CMDGROUP_LEN} EQUAL 0)
  32         message(FATAL_ERROR "libt2n CMDGROUP is empty")
  33     endif(${CMDGROUP_LEN} EQUAL 0)
  34
  35     include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR})
  36
  37     # Compute include directories
  38     # TODO: http://www.cmake.org/Bug/view.php?id=11889 contains a better solution
  39     get_property(gcc_include_dirs
  40         DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  41         PROPERTY INCLUDE_DIRECTORIES
  42     )
  43     set(gccxml_include_dirs "")
  44     foreach(gcc_include_dir ${gcc_include_dirs})
  45         set(gccxml_include_dirs "${gccxml_include_dirs} -I${gcc_include_dir}")
  46     endforeach(gcc_include_dir ${gcc_include_dirs})
  47
  48     foreach(CMDGROUP ${ARGV})
  49         message(STATUS "Processing libt2n command group ${CMDGROUP}")
  50
  51         # We are going to run each .cpp file through gccxml for the current CMDGROUP
  52         set(T2N_GCCXML_FILES "")
  53         set(T2N_GCCXML_COMMANDS "")
  54         foreach(T2NFILE ${${CMDGROUP}_GROUP})
  55             get_filename_component(FILE_NAME ${T2NFILE} NAME)
  56             get_filename_component(FILE_EXT ${T2NFILE} EXT)
  57             if(NOT FILE_EXT STREQUAL ".cpp")
  58                 message(FATAL_ERROR "   Error: ${FILE_NAME} is not a .cpp file based on its filename extension!")
  59             endif()
  60             message(STATUS "   Processing file ${FILE_NAME}")
  61
  62             # We build the commands in advance which execute gccxml on each file in the CMDGROUP
  63             set(T2N_GCCXML_COMMANDS ${T2N_GCCXML_COMMANDS}
  64                 COMMAND ${LIBT2N_GCCXML} ${gccxml_include_dirs} ${T2NFILE} -fxml=${T2NFILE}.xml
  65                 )
  66             # The filenames of the created intermediate gccxml files for the current CMDGROUP
  67             set(T2N_GCCXML_FILES ${T2N_GCCXML_FILES} ${T2NFILE}.xml)
  68         endforeach(T2NFILE ${${CMDGROUP}_GROUP})
  69
  70         add_custom_command(
  71             OUTPUT ${CMDGROUP}_common.cpp ${CMDGROUP}_common.hxx ${CMDGROUP}_client.cpp ${CMDGROUP}_client.hxx ${CMDGROUP}_server.cpp  ${CMDGROUP}_server.hxx
  72
  73             # Create dummy _common.hxx file
  74             COMMAND echo "\\#include \\\"codegen-stubhead.hxx\\\"" >${CMDGROUP}_common.hxx
  75             COMMAND echo "\\#include \\\"${CMDGROUP}.hxx\\\"" >>${CMDGROUP}_common.hxx
  76
  77             # Invoke gccxml on each source file in the current CMDGROUP and delete the dummy file
  78             ${T2N_GCCXML_COMMANDS}
  79             COMMAND rm -f ${CMDGROUP}_common.hxx
  80
  81             # Run the code generator on all the generated gccxml files and remove those intermediate gccxml files
  82             COMMAND ${LIBT2N_CODEGEN} ${CMDGROUP} ${T2N_GCCXML_FILES}
  83             COMMAND rm -f ${T2N_GCCXML_FILES}
  84
  85             DEPENDS ${${CMDGROUP}_GROUP}
  86             )
  87
  88         # Write out pkgconfig file
  89         configure_file(${LIBT2N_CLIENT_PCTEMPLATE} ${CMAKE_CURRENT_BINARY_DIR}/${CMDGROUP}.pc @ONLY@)
  90         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${CMDGROUP}.pc
  91             DESTINATION lib/pkgconfig)
  92
  93         # Create shared client library
  94         add_library(${CMDGROUP} SHARED ${CMDGROUP}_client.cpp ${CMDGROUP}_client.hxx)
  95         set_target_properties(${CMDGROUP} PROPERTIES VERSION ${VERSION} SOVERSION 1)
  96         target_link_libraries(${CMDGROUP} ${Boost_SERIALIZATION_LIBRARIES})
  97         install(TARGETS ${CMDGROUP} LIBRARY DESTINATION lib COMPONENT sharedlibs)
  98
  99         # Create static client library
 100         add_library(${CMDGROUP}-static STATIC ${CMDGROUP}_client.cpp ${CMDGROUP}_client.hxx)
 101         set_target_properties(${CMDGROUP}-static PROPERTIES OUTPUT_NAME "${CMDGROUP}")
 102         target_link_libraries(${CMDGROUP}-static ${Boost_SERIALIZATION_LIBRARIES})
 103         install(TARGETS ${CMDGROUP}-static ARCHIVE DESTINATION lib COMPONENT staticlibs)
 104
 105         # Prevent clobbering each other during the build
 106         set_target_properties(${CMDGROUP} PROPERTIES CLEAN_DIRECT_OUTPUT 1)
 107         set_target_properties(${CMDGROUP}-static PROPERTIES CLEAN_DIRECT_OUTPUT 1)
 108
 109         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${CMDGROUP}_client.hxx ${CMDGROUP}.hxx
 110                     DESTINATION include
 111                     COMPONENT headers
 112         )
 113
 114         # Wait till generated code is available
 115         add_custom_target(${CMDGROUP}_codegen_done ALL DEPENDS ${CMDGROUP}_common.cpp ${CMDGROUP}_common.hxx ${CMDGROUP}_client.cpp ${CMDGROUP}_client.hxx ${CMDGROUP}_server.cpp  ${CMDGROUP}_server.hxx)
 116         add_dependencies(${CMDGROUP} ${CMDGROUP}_codegen_done)
 117         add_dependencies(${CMDGROUP}-static ${CMDGROUP}_codegen_done)
 118
 119     endforeach(CMDGROUP ${ARGV})
 120 endfunction(setup_libt2n)