developer.intra2net.com Git - libi2ncommon/blob - CMakeLists.txt

   1 # Project
   2 project(libi2ncommon)
   3
   4 # Version settings
   5 set(VERSION 2.11)
   6
   7 SET(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}")
   8
   9 # CMake
  10 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  11    set(CMAKE_BUILD_TYPE     Debug)
  12 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  13 set(CMAKE_COLOR_MAKEFILE ON)
  14 cmake_minimum_required(VERSION 2.6 FATAL_ERROR)
  15
  16 # Debug build
  17 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  18 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  19    add_definitions(-DDEBUG)
  20 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  21
  22 # Enable all warnings
  23 add_definitions("-Wall")
  24
  25 # Set components
  26 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  27 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  28 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  29
  30 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  31 "Shared library for general use.")
  32 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  33 "C/C++ header files.")
  34
  35 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  36 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  37
  38 # Create suffix to eventually install in lib64
  39 IF(CMAKE_SIZEOF_VOID_P EQUAL 4)
  40     SET(LIB_SUFFIX "")
  41     SET(PACK_ARCH "")
  42   ELSE(CMAKE_SIZEOF_VOID_P EQUAL 4)
  43     SET(LIB_SUFFIX 64)
  44     SET(PACK_ARCH .x86_64)
  45 endif(CMAKE_SIZEOF_VOID_P EQUAL 4)
  46
  47 # Package information
  48 set(CPACK_PACKAGE_VERSION              ${VERSION})
  49 set(CPACK_PACKAGE_CONTACT              "Intra2net AG <libi2ncommon@developer.intra2net.com>")
  50 set(CPACK_PACKAGE_DESCRIPTION          "libi2ncommon library.")
  51 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION}
  52                                        )
  53 # Package settings
  54 set(CPACK_GENERATOR                    "DEB;RPM")
  55 set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
  56 set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
  57 set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})
  58
  59 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/Linking-Exception.txt)
  60 set(CPACK_RESOURCE_FILE_README         ${CMAKE_SOURCE_DIR}/COPYING.GPL)
  61
  62 set(CPACK_SOURCE_GENERATOR             TGZ)
  63 set(CPACK_SOURCE_IGNORE_FILES
  64     "~$"
  65     "\\\\.git"
  66     "build"
  67     "build-rpm"
  68 )
  69 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_FILE_NAME})
  70
  71 # "make dist" target
  72 set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION})
  73 add_custom_target(dist
  74     COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
  75             | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
  76     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
  77
  78 # documentation
  79 option(DOCUMENTATION "Generate API documentation with Doxygen" ON)
  80 find_package(Doxygen)
  81 if(DOCUMENTATION AND DOXYGEN_FOUND)
  82    # Set variables
  83    set(PACKAGE libi2ncommon)
  84    set(top_srcdir ${CMAKE_SOURCE_DIR})
  85
  86    # Find doxy config
  87    message(STATUS "Doxygen found.")
  88    set(DOXY_DIR "${CMAKE_SOURCE_DIR}/doc")
  89    set(DOXY_CONFIG "${DOXY_DIR}/Doxyfile.in")
  90
  91    # Copy doxy.config.in
  92    configure_file("${DOXY_CONFIG}" "${CMAKE_BINARY_DIR}/doxy.config")
  93
  94    # Create doc directory
  95    add_custom_command(
  96    OUTPUT ${CMAKE_BINARY_DIR}/doc
  97    COMMAND rm -rf ${CMAKE_BINARY_DIR}/doc/{html,man}
  98    COMMAND mkdir -p ${CMAKE_BINARY_DIR}/doc
  99    DEPENDS src configlib xmllib utils test
 100    )
 101
 102    # Run doxygen
 103    add_custom_command(
 104    OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html
 105    COMMAND ${DOXYGEN_EXECUTABLE} "${CMAKE_BINARY_DIR}/doxy.config"
 106    DEPENDS "${CMAKE_BINARY_DIR}/doxy.config" "${CMAKE_BINARY_DIR}/doc"
 107    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/doc
 108    )
 109
 110    add_custom_target(docs ALL DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html)
 111
 112    message(STATUS "Generating API documentation with Doxygen")
 113 else(DOCUMENTATION AND DOXYGEN_FOUND)
 114    message(STATUS "Not generating API documentation")
 115 endif(DOCUMENTATION AND DOXYGEN_FOUND)
 116
 117 # Conditional build itmes
 118 option(BUILD_XMLLIB "Build xml part of libi2ncommon - needs patched libxml++" OFF)
 119 if (BUILD_XMLLIB)
 120    message(STATUS "Build xml library part")
 121 else(BUILD_XMLLIB)
 122    message(STATUS "NOT building xml library part")
 123 endif(BUILD_XMLLIB)
 124
 125 option(IMAP_UTF7_SUPPORT "Enable imap modified utf7 support - needs patched libiconv" OFF)
 126 if (IMAP_UTF7_SUPPORT)
 127    message(STATUS "Build imap modified utf7 support")
 128 else(IMAP_UTF7_SUPPORT)
 129    message(STATUS "NOT building imap modified utf7 support")
 130 endif(IMAP_UTF7_SUPPORT)
 131
 132 # Find external packages
 133 include(FindPkgConfig)
 134
 135 # Find Boost
 136 find_package(Boost 1.44 COMPONENTS iostreams unit_test_framework thread REQUIRED)
 137
 138 # Find pcrecpp
 139 pkg_check_modules(PCRECPP REQUIRED libpcrecpp)
 140 INCLUDE_DIRECTORIES(${PCRECPP_INCLUDE_DIRS})
 141 LINK_DIRECTORIES(${PCRECPP_LIBRARY_DIRS})
 142
 143 # Find libxml++
 144 if (BUILD_XMLLIB)
 145     pkg_check_modules(XMLPP REQUIRED libxml++-2.6)
 146 endif(BUILD_XMLLIB)
 147
 148 # Find iconv
 149 if (IMAP_UTF7_SUPPORT)
 150     pkg_check_modules(ICONV REQUIRED libiconv)
 151     include_directories($ICONV_INCLUDE_DIRS})
 152     link_directories(${ICONV_LIBRARY_DIRS})
 153 endif(IMAP_UTF7_SUPPORT)
 154
 155 # Detect openssl - for base64 routines
 156 pkg_check_modules(OPENSSL REQUIRED openssl)
 157 INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIRS})
 158 LINK_DIRECTORIES(${OPENSSL_LIBRARY_DIRS})
 159
 160 # pkgconfig output
 161 set(prefix      ${CMAKE_INSTALL_PREFIX})
 162 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 163 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 164 set(libdir      ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
 165
 166 # construct ${BOOST_LDADD} from ${Boost_LIBRARIES}
 167 # forming "-L/some/path -lboost_a -L/other/path -lboost_b" from
 168 # "/some/path/libboost_a.so.3.5;/other/path/libboost_b.so"
 169 set(BOOST_LDADD "")
 170 FOREACH(boost_lib_full ${Boost_IOSTREAMS_LIBRARIES})
 171     get_filename_component(boost_lib_path ${boost_lib_full} PATH)
 172     get_filename_component(boost_lib_file ${boost_lib_full} NAME_WE)
 173     string(REGEX REPLACE "^lib(boost.+)$" "\\1" boost_lib_name ${boost_lib_file})
 174     set(BOOST_LDADD "${BOOST_LDADD} -L${boost_lib_path} -l${boost_lib_name}")
 175 ENDFOREACH()
 176
 177 # construct ${BOOST_CFLAGS} from ${Boost_INCLUDE_DIRS}
 178 string(REGEX REPLACE ";" " -I" BOOST_CFLAGS "${Boost_INCLUDE_DIRS}")
 179 set(BOOST_CFLAGS "-I${BOOST_CFLAGS}")
 180
 181 # construct ${ICONV_CFLAGS} from ${ICONV_INCLUDE_DIRS}
 182 string(REGEX REPLACE ";" " -I" ICONV_CFLAGS "${ICONV_INCLUDE_DIRS}")
 183 set(ICONV_CFLAGS "-I${ICONV_CFLAGS}")
 184
 185 configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon.pc @ONLY)
 186 configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon_config.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon_config.pc @ONLY)
 187 configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon_utils.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon_utils.pc @ONLY)
 188
 189 install(FILES ${CMAKE_BINARY_DIR}/libi2ncommon.pc
 190                      ${CMAKE_BINARY_DIR}/libi2ncommon_config.pc
 191                      ${CMAKE_BINARY_DIR}/libi2ncommon_utils.pc
 192         DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 193
 194 if (BUILD_XMLLIB)
 195     configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon_xml.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon_xml.pc @ONLY)
 196     install(FILES ${CMAKE_BINARY_DIR}/libi2ncommon_xml.pc DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 197 endif(BUILD_XMLLIB)
 198
 199
 200 include(CPack)
 201
 202 # Subdirectories
 203 set(CPACK_SET_DESTDIR "ON")
 204
 205 add_subdirectory(src)
 206 add_subdirectory(configlib)
 207 add_subdirectory(utils)
 208 add_subdirectory(test)
 209 if (BUILD_XMLLIB)
 210     add_subdirectory(xmllib)
 211 endif(BUILD_XMLLIB)