# Project
project(libi2ncommon)

# Version settings
set(VERSION 2.11)

SET(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}")

# CMake
if("${CMAKE_BUILD_TYPE}" STREQUAL "")
   set(CMAKE_BUILD_TYPE     Debug)
endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
set(CMAKE_COLOR_MAKEFILE ON)
cmake_minimum_required(VERSION 2.6 FATAL_ERROR)

# Debug build
message("-- Build type: ${CMAKE_BUILD_TYPE}")
if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
   add_definitions(-DDEBUG)
endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)

# Enable all warnings
add_definitions("-Wall")

# Set components
set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")

set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
"Shared library for general use.")
set(CPACK_COMPONENT_HEADERS_DESCRIPTION
"C/C++ header files.")

set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
set(CPACK_COMPONENT_HEADERS_GROUP    "Development")

# Create suffix to eventually install in lib64
IF(CMAKE_SIZEOF_VOID_P EQUAL 4)
    SET(LIB_SUFFIX "")
    SET(PACK_ARCH "")
  ELSE(CMAKE_SIZEOF_VOID_P EQUAL 4)
    SET(LIB_SUFFIX 64)
    SET(PACK_ARCH .x86_64)
endif(CMAKE_SIZEOF_VOID_P EQUAL 4)

# Package information
set(CPACK_PACKAGE_VERSION              ${VERSION})
set(CPACK_PACKAGE_CONTACT              "Intra2net AG <libi2ncommon@developer.intra2net.com>")
set(CPACK_PACKAGE_DESCRIPTION          "libi2ncommon library.")
set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION}
                                       )
# Package settings
set(CPACK_GENERATOR                    "DEB;RPM")
set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})

set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/Linking-Exception.txt)
set(CPACK_RESOURCE_FILE_README         ${CMAKE_SOURCE_DIR}/COPYING.GPL)

set(CPACK_SOURCE_GENERATOR             TGZ)
set(CPACK_SOURCE_IGNORE_FILES
    "~$"
    "\\\\.git"
    "build"
    "build-rpm"
)
set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_FILE_NAME})

# "make dist" target
set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION})
add_custom_target(dist
    COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
            | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})

# documentation
option(DOCUMENTATION "Generate API documentation with Doxygen" ON)
find_package(Doxygen)
if(DOCUMENTATION AND DOXYGEN_FOUND)
   # Set variables
   set(PACKAGE libi2ncommon)
   set(top_srcdir ${CMAKE_SOURCE_DIR})

   # Find doxy config
   message(STATUS "Doxygen found.")
   set(DOXY_DIR "${CMAKE_SOURCE_DIR}/doc")
   set(DOXY_CONFIG "${DOXY_DIR}/Doxyfile.in")

   # Copy doxy.config.in
   configure_file("${DOXY_CONFIG}" "${CMAKE_BINARY_DIR}/doxy.config")

   # Create doc directory
   add_custom_command(
   OUTPUT ${CMAKE_BINARY_DIR}/doc
   COMMAND rm -rf ${CMAKE_BINARY_DIR}/doc/{html,man}
   COMMAND mkdir -p ${CMAKE_BINARY_DIR}/doc
   DEPENDS src configlib xmllib utils test
   )

   # Run doxygen
   add_custom_command(
   OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html
   COMMAND ${DOXYGEN_EXECUTABLE} "${CMAKE_BINARY_DIR}/doxy.config"
   DEPENDS "${CMAKE_BINARY_DIR}/doxy.config" "${CMAKE_BINARY_DIR}/doc"
   WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/doc
   )

   add_custom_target(docs ALL DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html)

   message(STATUS "Generating API documentation with Doxygen")
else(DOCUMENTATION AND DOXYGEN_FOUND)
   message(STATUS "Not generating API documentation")
endif(DOCUMENTATION AND DOXYGEN_FOUND)

# Conditional build itmes
option(BUILD_XMLLIB "Build xml part of libi2ncommon - needs patched libxml++" OFF)
if (BUILD_XMLLIB)
   message(STATUS "Build xml library part")
else(BUILD_XMLLIB)
   message(STATUS "NOT building xml library part")
endif(BUILD_XMLLIB)

option(IMAP_UTF7_SUPPORT "Enable imap modified utf7 support - needs patched libiconv" OFF)
if (IMAP_UTF7_SUPPORT)
   message(STATUS "Build imap modified utf7 support")
else(IMAP_UTF7_SUPPORT)
   message(STATUS "NOT building imap modified utf7 support")
endif(IMAP_UTF7_SUPPORT)

# Find external packages
include(FindPkgConfig)

# Find Boost
find_package(Boost 1.44 COMPONENTS iostreams unit_test_framework thread REQUIRED)

# Find pcrecpp
pkg_check_modules(PCRECPP REQUIRED libpcrecpp)
INCLUDE_DIRECTORIES(${PCRECPP_INCLUDE_DIRS})
LINK_DIRECTORIES(${PCRECPP_LIBRARY_DIRS})

# Find libxml++
if (BUILD_XMLLIB)
    pkg_check_modules(XMLPP REQUIRED libxml++-2.6)
endif(BUILD_XMLLIB)

# Find iconv
if (IMAP_UTF7_SUPPORT)
    pkg_check_modules(ICONV REQUIRED libiconv)
    include_directories($ICONV_INCLUDE_DIRS})
    link_directories(${ICONV_LIBRARY_DIRS})
endif(IMAP_UTF7_SUPPORT)

# Detect openssl - for base64 routines
pkg_check_modules(OPENSSL REQUIRED openssl)
INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIRS})
LINK_DIRECTORIES(${OPENSSL_LIBRARY_DIRS})

# pkgconfig output
set(prefix      ${CMAKE_INSTALL_PREFIX})
set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
set(libdir      ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})

# construct ${BOOST_LDADD} from ${Boost_LIBRARIES}
# forming "-L/some/path -lboost_a -L/other/path -lboost_b" from
# "/some/path/libboost_a.so.3.5;/other/path/libboost_b.so"
set(BOOST_LDADD "")
FOREACH(boost_lib_full ${Boost_IOSTREAMS_LIBRARIES})
    get_filename_component(boost_lib_path ${boost_lib_full} PATH)
    get_filename_component(boost_lib_file ${boost_lib_full} NAME_WE)
    string(REGEX REPLACE "^lib(boost.+)$" "\\1" boost_lib_name ${boost_lib_file})
    set(BOOST_LDADD "${BOOST_LDADD} -L${boost_lib_path} -l${boost_lib_name}")
ENDFOREACH()

# construct ${BOOST_CFLAGS} from ${Boost_INCLUDE_DIRS}
string(REGEX REPLACE ";" " -I" BOOST_CFLAGS "${Boost_INCLUDE_DIRS}")
set(BOOST_CFLAGS "-I${BOOST_CFLAGS}")

# construct ${ICONV_CFLAGS} from ${ICONV_INCLUDE_DIRS}
string(REGEX REPLACE ";" " -I" ICONV_CFLAGS "${ICONV_INCLUDE_DIRS}")
set(ICONV_CFLAGS "-I${ICONV_CFLAGS}")

configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon.pc @ONLY)
configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon_config.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon_config.pc @ONLY)
configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon_utils.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon_utils.pc @ONLY)

install(FILES ${CMAKE_BINARY_DIR}/libi2ncommon.pc
                     ${CMAKE_BINARY_DIR}/libi2ncommon_config.pc
                     ${CMAKE_BINARY_DIR}/libi2ncommon_utils.pc
        DESTINATION lib${LIB_SUFFIX}/pkgconfig)

if (BUILD_XMLLIB)
    configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon_xml.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon_xml.pc @ONLY)
    install(FILES ${CMAKE_BINARY_DIR}/libi2ncommon_xml.pc DESTINATION lib${LIB_SUFFIX}/pkgconfig)
endif(BUILD_XMLLIB)


include(CPack)

# Subdirectories
set(CPACK_SET_DESTDIR "ON")

add_subdirectory(src)
add_subdirectory(configlib)
add_subdirectory(utils)
add_subdirectory(test)
if (BUILD_XMLLIB)
    add_subdirectory(xmllib)
endif(BUILD_XMLLIB)