developer.intra2net.com Git - libftdi/blob - CMakeLists.txt

   1 # Project
   2 project(libftdi1)
   3 set(MAJOR_VERSION 1)
   4 set(MINOR_VERSION 0)
   5 set(PACKAGE libftdi1)
   6 set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION})
   7 set(VERSION ${VERSION_STRING})
   8 SET(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}")
   9
  10 # CMake
  11 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  12    set(CMAKE_BUILD_TYPE     RelWithDebInfo)
  13 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  14 set(CMAKE_COLOR_MAKEFILE ON)
  15 cmake_minimum_required(VERSION 2.6 FATAL_ERROR)
  16
  17 add_definitions(-Wall)
  18
  19 # Debug build
  20 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  21 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  22    add_definitions(-DDEBUG)
  23 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  24
  25 # find libusb
  26 find_package ( USB1 REQUIRED )
  27 include_directories ( ${LIBUSB_INCLUDE_DIR} )
  28
  29 # Find Boost (optional package)
  30 find_package(Boost)
  31
  32 # Set components
  33 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  34 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  35 set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries")
  36 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  37
  38 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  39 "Shared library for general use.")
  40 set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION
  41 "Static library, good if you want to embed libftdi1 in your application.")
  42 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  43 "C/C++ header files.")
  44
  45 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  46 set(CPACK_COMPONENT_STATICLIBS_GROUP "Development")
  47 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  48
  49 # automatically set lib suffix
  50 if ( UNIX AND NOT APPLE AND NOT CMAKE_CROSSCOMPILING AND NOT EXISTS "/etc/debian_version" )
  51   if ( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT LIB_SUFFIX )
  52     set ( LIB_SUFFIX 64 )
  53   endif ()
  54 endif ()
  55
  56 if(NOT APPLE)
  57   if(CMAKE_SIZEOF_VOID_P EQUAL 4)
  58       SET(PACK_ARCH "")
  59     else(CMAKE_SIZEOF_VOID_P EQUAL 8)
  60       SET(PACK_ARCH .x86_64)
  61   endif(CMAKE_SIZEOF_VOID_P EQUAL 4)
  62 else(NOT APPLE)
  63   SET(PACK_ARCH "")
  64 endif(NOT APPLE)
  65
  66 # Package information
  67 set(CPACK_PACKAGE_VERSION              ${VERSION_STRING})
  68 set(CPACK_PACKAGE_CONTACT              "Intra2net AG <libftdi@developer.intra2net.com>")
  69 set(CPACK_PACKAGE_DESCRIPTION          "libftdi1 library.")
  70 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION}
  71                                        )
  72 # Package settings
  73 if ( UNIX )
  74   set(CPACK_GENERATOR                    "DEB;RPM")
  75   set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
  76   set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
  77   set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})
  78 endif ()
  79
  80 if ( WIN32 )
  81   set ( CPACK_GENERATOR                    "NSIS" )
  82   set ( CPACK_CMAKE_GENERATOR              "MinGW Makefiles" )
  83   set ( CPACK_PACKAGE_NAME                 "${PROJECT_NAME}" )
  84   set ( CPACK_PACKAGE_VENDOR               "" )
  85   set ( CPACK_PACKAGE_INSTALL_DIRECTORY    "libftdi1" )
  86   set ( CPACK_PACKAGE_FILE_NAME            "${PROJECT_NAME}-${VERSION_STRING}-win32")
  87   set ( CPACK_NSIS_DISPLAY_NAME            "libftdi1" )
  88   set ( CPACK_NSIS_MODIFY_PATH             ON )
  89 endif ()
  90
  91 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/LICENSE)
  92
  93 set(CPACK_SOURCE_GENERATOR             TGZ)
  94 set(CPACK_SOURCE_IGNORE_FILES          "\\\\.git;~$;build/")
  95 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION})
  96
  97 # Subdirectories
  98 if ( UNIX )
  99   set ( CPACK_SET_DESTDIR ON )
 100 endif ()
 101
 102 # "make dist" target
 103 set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION_STRING})
 104 add_custom_target(dist
 105     COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
 106             | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
 107     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 108
 109
 110 # Documentation
 111 option ( DOCUMENTATION "Generate API documentation with Doxygen" ON )
 112
 113
 114 find_package ( Doxygen )
 115 if ( DOCUMENTATION AND DOXYGEN_FOUND )
 116
 117    # Find doxy config
 118    message(STATUS "Doxygen found.")
 119
 120    # Copy doxy.config.in
 121    set(top_srcdir ${CMAKE_SOURCE_DIR})
 122    configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.in ${CMAKE_BINARY_DIR}/Doxyfile )
 123    configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.xml.in ${CMAKE_BINARY_DIR}/Doxyfile.xml )
 124
 125    # Run doxygen
 126    add_custom_command(
 127     OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html
 128     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc
 129     COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile
 130     DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers}
 131    )
 132
 133    add_custom_target(docs ALL DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html)
 134
 135    message(STATUS "Generating API documentation with Doxygen")
 136 else(DOCUMENTATION AND DOXYGEN_FOUND)
 137    message(STATUS "Not generating API documentation")
 138 endif(DOCUMENTATION AND DOXYGEN_FOUND)
 139
 140 add_subdirectory(src)
 141 add_subdirectory(ftdipp)
 142 add_subdirectory(bindings)
 143 add_subdirectory(ftdi_eeprom)
 144 add_subdirectory(examples)
 145 add_subdirectory(packages)
 146 add_subdirectory(test)
 147
 148 # PkgConfig
 149 set(prefix      ${CMAKE_INSTALL_PREFIX})
 150 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 151 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 152
 153 if(${UNIX})
 154    set(libdir      ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
 155 endif(${UNIX})
 156 if(${WIN32})
 157    set(libdir      ${CMAKE_INSTALL_PREFIX}/bin)
 158 endif(${WIN32})
 159
 160 configure_file(${CMAKE_SOURCE_DIR}/libftdi1.spec.in ${CMAKE_BINARY_DIR}/libftdi1.spec @ONLY)
 161 configure_file(${CMAKE_SOURCE_DIR}/libftdi1.pc.in ${CMAKE_BINARY_DIR}/libftdi1.pc @ONLY)
 162 configure_file(${CMAKE_SOURCE_DIR}/libftdipp1.pc.in ${CMAKE_BINARY_DIR}/libftdipp1.pc @ONLY)
 163 install(FILES ${CMAKE_BINARY_DIR}/libftdi1.pc ${CMAKE_BINARY_DIR}/libftdipp1.pc
 164         DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 165
 166 if ( UNIX )
 167   configure_file ( libftdi1-config.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config @ONLY )
 168   install ( PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config
 169             DESTINATION bin )
 170
 171   # config script install path
 172   if ( NOT DEFINED LIBFTDI_CMAKE_CONFIG_DIR )
 173     set ( LIBFTDI_CMAKE_CONFIG_DIR lib${LIB_SUFFIX}/cmake/libftdi1 )
 174   endif ()
 175
 176   get_target_property( _LIBFTDI_LIBRARY_LOCATION ftdi1 LOCATION )
 177   get_filename_component ( _LIBFTDI_LIBRARY_NAME ${_LIBFTDI_LIBRARY_LOCATION} NAME )
 178   set ( LIBFTDI_INCLUDE_DIR ${includedir} )
 179   set ( LIBFTDI_INCLUDE_DIRS ${LIBFTDI_INCLUDE_DIR} )
 180   set ( LIBFTDI_LIBRARY ${libdir}/${_LIBFTDI_LIBRARY_NAME} )
 181   set ( LIBFTDI_LIBRARIES ${LIBFTDI_LIBRARY} )
 182   list ( APPEND LIBFTDI_LIBRARIES ${LIBUSB_LIBRARIES} )
 183   set ( LIBFTDI_ROOT_DIR ${prefix} )
 184   set ( LIBFTDI_VERSION_STRING ${VERSION_STRING} )
 185   set ( LIBFTDI_VERSION_MAJOR ${MAJOR_VERSION} )
 186   set ( LIBFTDI_VERSION_MINOR ${MINOR_VERSION} )
 187
 188   set ( LIBFTDI_USE_FILE ${CMAKE_INSTALL_PREFIX}/${LIBFTDI_CMAKE_CONFIG_DIR}/UseLibFTDI1.cmake )
 189   configure_file ( LibFTDI1Config.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake @ONLY )
 190   install ( FILES ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake UseLibFTDI1.cmake
 191             DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR}
 192           )
 193 endif ()
 194
 195 include(CPack)