| 1 | cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR) |
| 2 | |
| 3 | # Project |
| 4 | project(libftdi1 C) |
| 5 | set(MAJOR_VERSION 1) |
| 6 | set(MINOR_VERSION 5) |
| 7 | set(PACKAGE libftdi1) |
| 8 | set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION}) |
| 9 | set(VERSION ${VERSION_STRING}) |
| 10 | set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake) |
| 11 | |
| 12 | # CMake |
| 13 | if("${CMAKE_BUILD_TYPE}" STREQUAL "") |
| 14 | set(CMAKE_BUILD_TYPE RelWithDebInfo) |
| 15 | endif("${CMAKE_BUILD_TYPE}" STREQUAL "") |
| 16 | set(CMAKE_COLOR_MAKEFILE ON) |
| 17 | |
| 18 | add_definitions(-Wall) |
| 19 | |
| 20 | include(CMakeOptions.txt) |
| 21 | |
| 22 | # Debug build |
| 23 | message("-- Build type: ${CMAKE_BUILD_TYPE}") |
| 24 | if(${CMAKE_BUILD_TYPE} STREQUAL Debug) |
| 25 | add_definitions(-DDEBUG) |
| 26 | endif(${CMAKE_BUILD_TYPE} STREQUAL Debug) |
| 27 | |
| 28 | # find libusb |
| 29 | find_package( PkgConfig ) |
| 30 | if (PkgConfig_FOUND) |
| 31 | pkg_check_modules( LIBUSB libusb-1.0 ) |
| 32 | if (LIBUSB_FOUND) |
| 33 | include_directories ( ${LIBUSB_INCLUDE_DIRS} ) |
| 34 | else() |
| 35 | find_package ( USB1 REQUIRED ) |
| 36 | include_directories ( ${LIBUSB_INCLUDE_DIR} ) |
| 37 | endif() |
| 38 | endif() |
| 39 | |
| 40 | # Find Boost |
| 41 | if (FTDIPP OR BUILD_TESTS) |
| 42 | find_package( Boost REQUIRED ) |
| 43 | endif() |
| 44 | |
| 45 | # Set components |
| 46 | set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers) |
| 47 | set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries") |
| 48 | set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries") |
| 49 | set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers") |
| 50 | |
| 51 | set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION |
| 52 | "Shared library for general use.") |
| 53 | set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION |
| 54 | "Static library, good if you want to embed libftdi1 in your application.") |
| 55 | set(CPACK_COMPONENT_HEADERS_DESCRIPTION |
| 56 | "C/C++ header files.") |
| 57 | |
| 58 | set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development") |
| 59 | set(CPACK_COMPONENT_STATICLIBS_GROUP "Development") |
| 60 | set(CPACK_COMPONENT_HEADERS_GROUP "Development") |
| 61 | |
| 62 | # guess LIB_SUFFIX, don't take debian multiarch into account |
| 63 | if ( NOT DEFINED LIB_SUFFIX ) |
| 64 | if( CMAKE_SYSTEM_NAME MATCHES "Linux" |
| 65 | AND NOT CMAKE_CROSSCOMPILING |
| 66 | AND NOT EXISTS "/etc/debian_version" |
| 67 | AND NOT EXISTS "/etc/arch-release" ) |
| 68 | if ( "${CMAKE_SIZEOF_VOID_P}" EQUAL "8" ) |
| 69 | set ( LIB_SUFFIX 64 ) |
| 70 | endif () |
| 71 | endif () |
| 72 | endif () |
| 73 | |
| 74 | if(NOT APPLE) |
| 75 | if(CMAKE_SIZEOF_VOID_P EQUAL 4) |
| 76 | SET(PACK_ARCH "") |
| 77 | else(CMAKE_SIZEOF_VOID_P EQUAL 8) |
| 78 | SET(PACK_ARCH .x86_64) |
| 79 | endif(CMAKE_SIZEOF_VOID_P EQUAL 4) |
| 80 | else(NOT APPLE) |
| 81 | SET(PACK_ARCH "") |
| 82 | endif(NOT APPLE) |
| 83 | |
| 84 | # Package information |
| 85 | set(CPACK_PACKAGE_VERSION ${VERSION_STRING}) |
| 86 | set(CPACK_PACKAGE_CONTACT "Intra2net AG <libftdi@developer.intra2net.com>") |
| 87 | set(CPACK_PACKAGE_DESCRIPTION "libftdi1 library.") |
| 88 | set(CPACK_PACKAGE_DESCRIPTION_SUMMARY ${CPACK_PACKAGE_DESCRIPTION}) |
| 89 | |
| 90 | # Package settings |
| 91 | if ( UNIX ) |
| 92 | set(CPACK_GENERATOR "DEB;RPM") |
| 93 | set(CPACK_CMAKE_GENERATOR "Unix Makefiles") |
| 94 | set(CPACK_PACKAGE_NAME ${PROJECT_NAME}) |
| 95 | set(CPACK_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH}) |
| 96 | endif () |
| 97 | |
| 98 | if ( WIN32 ) |
| 99 | set ( CPACK_GENERATOR "NSIS" ) |
| 100 | set ( CPACK_CMAKE_GENERATOR "MinGW Makefiles" ) |
| 101 | set ( CPACK_PACKAGE_NAME "${PROJECT_NAME}" ) |
| 102 | set ( CPACK_PACKAGE_VENDOR "" ) |
| 103 | set ( CPACK_PACKAGE_INSTALL_DIRECTORY "libftdi1" ) |
| 104 | set ( CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32") |
| 105 | set ( CPACK_NSIS_DISPLAY_NAME "libftdi1" ) |
| 106 | set ( CPACK_NSIS_MODIFY_PATH ON ) |
| 107 | endif () |
| 108 | |
| 109 | set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE) |
| 110 | |
| 111 | set(CPACK_SOURCE_GENERATOR TGZ) |
| 112 | set(CPACK_SOURCE_IGNORE_FILES "\\\\.git;~$;build/") |
| 113 | set(CPACK_SOURCE_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}) |
| 114 | |
| 115 | # Subdirectories |
| 116 | if ( UNIX ) |
| 117 | set ( CPACK_SET_DESTDIR ON ) |
| 118 | endif () |
| 119 | |
| 120 | # "make dist" target |
| 121 | set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION_STRING}) |
| 122 | add_custom_target(dist |
| 123 | COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD |
| 124 | | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2 |
| 125 | WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}) |
| 126 | |
| 127 | if ( DOCUMENTATION ) |
| 128 | find_package ( Doxygen REQUIRED) |
| 129 | |
| 130 | # Copy doxy.config.in |
| 131 | set(top_srcdir ${CMAKE_SOURCE_DIR}) |
| 132 | configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.in ${CMAKE_BINARY_DIR}/Doxyfile ) |
| 133 | configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.xml.in ${CMAKE_BINARY_DIR}/Doxyfile.xml ) |
| 134 | |
| 135 | # Run doxygen |
| 136 | add_custom_command( |
| 137 | OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html |
| 138 | COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc |
| 139 | COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile |
| 140 | COMMENT "Generating API documentation" |
| 141 | DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers} |
| 142 | ) |
| 143 | |
| 144 | add_custom_target( |
| 145 | docs ALL |
| 146 | COMMENT "Documentation target docs" |
| 147 | DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html |
| 148 | ) |
| 149 | endif ( DOCUMENTATION ) |
| 150 | |
| 151 | add_subdirectory(src) |
| 152 | if ( FTDIPP ) |
| 153 | project(libftdi1 C CXX) |
| 154 | add_subdirectory(ftdipp) |
| 155 | endif () |
| 156 | if ( PYTHON_BINDINGS ) |
| 157 | add_subdirectory(python) |
| 158 | endif () |
| 159 | if ( FTDI_EEPROM ) |
| 160 | add_subdirectory(ftdi_eeprom) |
| 161 | endif () |
| 162 | if ( EXAMPLES ) |
| 163 | add_subdirectory(examples) |
| 164 | endif () |
| 165 | add_subdirectory(packages) |
| 166 | if ( BUILD_TESTS ) |
| 167 | project(libftdi1 C CXX) |
| 168 | add_subdirectory(test) |
| 169 | endif () |
| 170 | |
| 171 | # PkgConfig |
| 172 | set(prefix ${CMAKE_INSTALL_PREFIX}) |
| 173 | set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin) |
| 174 | set(includedir ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME}) |
| 175 | |
| 176 | if(${UNIX}) |
| 177 | set(libdir ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}) |
| 178 | endif(${UNIX}) |
| 179 | if(${WIN32}) |
| 180 | set(libdir ${CMAKE_INSTALL_PREFIX}/bin) |
| 181 | endif(${WIN32}) |
| 182 | |
| 183 | configure_file(${CMAKE_SOURCE_DIR}/libftdi1.pc.in ${CMAKE_BINARY_DIR}/libftdi1.pc @ONLY) |
| 184 | configure_file(${CMAKE_SOURCE_DIR}/libftdipp1.pc.in ${CMAKE_BINARY_DIR}/libftdipp1.pc @ONLY) |
| 185 | install(FILES ${CMAKE_BINARY_DIR}/libftdi1.pc ${CMAKE_BINARY_DIR}/libftdipp1.pc |
| 186 | DESTINATION lib${LIB_SUFFIX}/pkgconfig) |
| 187 | |
| 188 | if (UNIX OR MINGW) |
| 189 | configure_file ( libftdi1-config.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config @ONLY ) |
| 190 | install ( PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config |
| 191 | DESTINATION bin ) |
| 192 | endif () |
| 193 | |
| 194 | # config script install path |
| 195 | if ( NOT DEFINED LIBFTDI_CMAKE_CONFIG_DIR ) |
| 196 | set ( LIBFTDI_CMAKE_CONFIG_DIR lib${LIB_SUFFIX}/cmake/libftdi1 ) |
| 197 | endif () |
| 198 | |
| 199 | set ( LIBFTDI_INCLUDE_DIR ${includedir} ) |
| 200 | set ( LIBFTDI_INCLUDE_DIRS ${LIBFTDI_INCLUDE_DIR} ) |
| 201 | set ( LIBFTDI_LIBRARY ftdi1 ) |
| 202 | set ( LIBFTDI_LIBRARIES ${LIBFTDI_LIBRARY} ) |
| 203 | list ( APPEND LIBFTDI_LIBRARIES ${LIBUSB_LIBRARIES} ) |
| 204 | set ( LIBFTDI_STATIC_LIBRARY ftdi1.a ) |
| 205 | set ( LIBFTDI_STATIC_LIBRARIES ${LIBFTDI_STATIC_LIBRARY} ) |
| 206 | list ( APPEND LIBFTDI_STATIC_LIBRARIES ${LIBUSB_LIBRARIES} ) |
| 207 | if ( FTDIPP ) |
| 208 | set ( LIBFTDIPP_LIBRARY ftdipp1 ) |
| 209 | set ( LIBFTDIPP_LIBRARIES ${LIBFTDIPP_LIBRARY} ) |
| 210 | list ( APPEND LIBFTDIPP_LIBRARIES ${LIBUSB_LIBRARIES} ) |
| 211 | endif () |
| 212 | set ( LIBFTDI_LIBRARY_DIRS ${libdir} ) |
| 213 | set ( LIBFTDI_ROOT_DIR ${prefix} ) |
| 214 | set ( LIBFTDI_VERSION_STRING ${VERSION_STRING} ) |
| 215 | set ( LIBFTDI_VERSION_MAJOR ${MAJOR_VERSION} ) |
| 216 | set ( LIBFTDI_VERSION_MINOR ${MINOR_VERSION} ) |
| 217 | |
| 218 | set ( LIBFTDI_USE_FILE ${CMAKE_INSTALL_PREFIX}/${LIBFTDI_CMAKE_CONFIG_DIR}/UseLibFTDI1.cmake ) |
| 219 | |
| 220 | include(CMakePackageConfigHelpers) |
| 221 | |
| 222 | configure_package_config_file ( |
| 223 | cmake/LibFTDI1Config.cmake.in |
| 224 | ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake |
| 225 | INSTALL_DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR} |
| 226 | PATH_VARS |
| 227 | LIBFTDI_USE_FILE |
| 228 | LIBFTDI_ROOT_DIR |
| 229 | LIBFTDI_INCLUDE_DIR |
| 230 | LIBFTDI_INCLUDE_DIRS |
| 231 | LIBFTDI_LIBRARY_DIRS |
| 232 | NO_CHECK_REQUIRED_COMPONENTS_MACRO |
| 233 | ) |
| 234 | write_basic_package_version_file ( |
| 235 | LibFTDI1ConfigVersion.cmake |
| 236 | VERSION ${LIBFTDI_VERSION_STRING} |
| 237 | COMPATIBILITY AnyNewerVersion |
| 238 | ) |
| 239 | |
| 240 | install ( |
| 241 | FILES |
| 242 | ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake |
| 243 | ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1ConfigVersion.cmake |
| 244 | cmake/UseLibFTDI1.cmake |
| 245 | DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR} |
| 246 | ) |
| 247 | |
| 248 | include(CPack) |
| 249 | |
| 250 | message (STATUS "Summary of build options: |
| 251 | |
| 252 | Build static libs: ${STATICLIBS} |
| 253 | Build C++ bindings: ${FTDIPP} |
| 254 | Build Python bindings: ${PYTHON_BINDINGS} |
| 255 | Build ftdi_eeprom: ${FTDI_EEPROM} |
| 256 | Build examples: ${EXAMPLES} |
| 257 | Build tests: ${BUILD_TESTS} |
| 258 | Build API documentation: ${DOCUMENTATION} |
| 259 | ") |