| 1 | # Project |
| 2 | project(libftdi1) |
| 3 | set(MAJOR_VERSION 1) |
| 4 | set(MINOR_VERSION 1) |
| 5 | set(PACKAGE libftdi1) |
| 6 | set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION}) |
| 7 | set(VERSION ${VERSION_STRING}) |
| 8 | set ( CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake ) |
| 9 | |
| 10 | # CMake |
| 11 | if("${CMAKE_BUILD_TYPE}" STREQUAL "") |
| 12 | set(CMAKE_BUILD_TYPE RelWithDebInfo) |
| 13 | endif("${CMAKE_BUILD_TYPE}" STREQUAL "") |
| 14 | set(CMAKE_COLOR_MAKEFILE ON) |
| 15 | cmake_minimum_required(VERSION 2.6 FATAL_ERROR) |
| 16 | |
| 17 | add_definitions(-Wall) |
| 18 | |
| 19 | # Debug build |
| 20 | message("-- Build type: ${CMAKE_BUILD_TYPE}") |
| 21 | if(${CMAKE_BUILD_TYPE} STREQUAL Debug) |
| 22 | add_definitions(-DDEBUG) |
| 23 | endif(${CMAKE_BUILD_TYPE} STREQUAL Debug) |
| 24 | |
| 25 | # find libusb |
| 26 | find_package ( USB1 REQUIRED ) |
| 27 | include_directories ( ${LIBUSB_INCLUDE_DIR} ) |
| 28 | |
| 29 | # Find Boost (optional package) |
| 30 | find_package(Boost) |
| 31 | |
| 32 | # Set components |
| 33 | set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers) |
| 34 | set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries") |
| 35 | set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries") |
| 36 | set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers") |
| 37 | |
| 38 | set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION |
| 39 | "Shared library for general use.") |
| 40 | set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION |
| 41 | "Static library, good if you want to embed libftdi1 in your application.") |
| 42 | set(CPACK_COMPONENT_HEADERS_DESCRIPTION |
| 43 | "C/C++ header files.") |
| 44 | |
| 45 | set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development") |
| 46 | set(CPACK_COMPONENT_STATICLIBS_GROUP "Development") |
| 47 | set(CPACK_COMPONENT_HEADERS_GROUP "Development") |
| 48 | |
| 49 | option ( STATICLIBS "Build static libraries" ON ) |
| 50 | |
| 51 | # guess LIB_SUFFIX, don't take debian multiarch into account |
| 52 | if ( NOT DEFINED LIB_SUFFIX ) |
| 53 | if( CMAKE_SYSTEM_NAME MATCHES "Linux" |
| 54 | AND NOT CMAKE_CROSSCOMPILING |
| 55 | AND NOT EXISTS "/etc/debian_version" |
| 56 | AND NOT EXISTS "/etc/arch-release" ) |
| 57 | if ( "${CMAKE_SIZEOF_VOID_P}" EQUAL "8" ) |
| 58 | set ( LIB_SUFFIX 64 ) |
| 59 | endif () |
| 60 | endif () |
| 61 | endif () |
| 62 | |
| 63 | if(NOT APPLE) |
| 64 | if(CMAKE_SIZEOF_VOID_P EQUAL 4) |
| 65 | SET(PACK_ARCH "") |
| 66 | else(CMAKE_SIZEOF_VOID_P EQUAL 8) |
| 67 | SET(PACK_ARCH .x86_64) |
| 68 | endif(CMAKE_SIZEOF_VOID_P EQUAL 4) |
| 69 | else(NOT APPLE) |
| 70 | SET(PACK_ARCH "") |
| 71 | endif(NOT APPLE) |
| 72 | |
| 73 | # Package information |
| 74 | set(CPACK_PACKAGE_VERSION ${VERSION_STRING}) |
| 75 | set(CPACK_PACKAGE_CONTACT "Intra2net AG <libftdi@developer.intra2net.com>") |
| 76 | set(CPACK_PACKAGE_DESCRIPTION "libftdi1 library.") |
| 77 | set(CPACK_PACKAGE_DESCRIPTION_SUMMARY ${CPACK_PACKAGE_DESCRIPTION} |
| 78 | ) |
| 79 | # Package settings |
| 80 | if ( UNIX ) |
| 81 | set(CPACK_GENERATOR "DEB;RPM") |
| 82 | set(CPACK_CMAKE_GENERATOR "Unix Makefiles") |
| 83 | set(CPACK_PACKAGE_NAME ${PROJECT_NAME}) |
| 84 | set(CPACK_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH}) |
| 85 | endif () |
| 86 | |
| 87 | if ( WIN32 ) |
| 88 | set ( CPACK_GENERATOR "NSIS" ) |
| 89 | set ( CPACK_CMAKE_GENERATOR "MinGW Makefiles" ) |
| 90 | set ( CPACK_PACKAGE_NAME "${PROJECT_NAME}" ) |
| 91 | set ( CPACK_PACKAGE_VENDOR "" ) |
| 92 | set ( CPACK_PACKAGE_INSTALL_DIRECTORY "libftdi1" ) |
| 93 | set ( CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32") |
| 94 | set ( CPACK_NSIS_DISPLAY_NAME "libftdi1" ) |
| 95 | set ( CPACK_NSIS_MODIFY_PATH ON ) |
| 96 | endif () |
| 97 | |
| 98 | set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE) |
| 99 | |
| 100 | set(CPACK_SOURCE_GENERATOR TGZ) |
| 101 | set(CPACK_SOURCE_IGNORE_FILES "\\\\.git;~$;build/") |
| 102 | set(CPACK_SOURCE_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}) |
| 103 | |
| 104 | # Subdirectories |
| 105 | if ( UNIX ) |
| 106 | set ( CPACK_SET_DESTDIR ON ) |
| 107 | endif () |
| 108 | |
| 109 | # "make dist" target |
| 110 | set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION_STRING}) |
| 111 | add_custom_target(dist |
| 112 | COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD |
| 113 | | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2 |
| 114 | WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}) |
| 115 | |
| 116 | # Tests |
| 117 | option ( BUILD_TESTS "Build unit tests with Boost Unit Test framework" ON ) |
| 118 | |
| 119 | # Documentation |
| 120 | option ( DOCUMENTATION "Generate API documentation with Doxygen" ON ) |
| 121 | |
| 122 | |
| 123 | find_package ( Doxygen ) |
| 124 | if ( DOCUMENTATION AND DOXYGEN_FOUND ) |
| 125 | |
| 126 | # Find doxy config |
| 127 | message(STATUS "Doxygen found.") |
| 128 | |
| 129 | # Copy doxy.config.in |
| 130 | set(top_srcdir ${CMAKE_SOURCE_DIR}) |
| 131 | configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.in ${CMAKE_BINARY_DIR}/Doxyfile ) |
| 132 | configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.xml.in ${CMAKE_BINARY_DIR}/Doxyfile.xml ) |
| 133 | |
| 134 | # Run doxygen |
| 135 | add_custom_command( |
| 136 | OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html |
| 137 | COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc |
| 138 | COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile |
| 139 | DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers} |
| 140 | ) |
| 141 | |
| 142 | add_custom_target(docs ALL DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html) |
| 143 | |
| 144 | message(STATUS "Generating API documentation with Doxygen") |
| 145 | else(DOCUMENTATION AND DOXYGEN_FOUND) |
| 146 | message(STATUS "Not generating API documentation") |
| 147 | endif(DOCUMENTATION AND DOXYGEN_FOUND) |
| 148 | |
| 149 | add_subdirectory(src) |
| 150 | add_subdirectory(ftdipp) |
| 151 | add_subdirectory(python) |
| 152 | add_subdirectory(ftdi_eeprom) |
| 153 | add_subdirectory(examples) |
| 154 | add_subdirectory(packages) |
| 155 | add_subdirectory(test) |
| 156 | |
| 157 | # PkgConfig |
| 158 | set(prefix ${CMAKE_INSTALL_PREFIX}) |
| 159 | set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin) |
| 160 | set(includedir ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME}) |
| 161 | |
| 162 | if(${UNIX}) |
| 163 | set(libdir ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}) |
| 164 | endif(${UNIX}) |
| 165 | if(${WIN32}) |
| 166 | set(libdir ${CMAKE_INSTALL_PREFIX}/bin) |
| 167 | endif(${WIN32}) |
| 168 | |
| 169 | configure_file(${CMAKE_SOURCE_DIR}/libftdi1.spec.in ${CMAKE_BINARY_DIR}/libftdi1.spec @ONLY) |
| 170 | configure_file(${CMAKE_SOURCE_DIR}/libftdi1.pc.in ${CMAKE_BINARY_DIR}/libftdi1.pc @ONLY) |
| 171 | configure_file(${CMAKE_SOURCE_DIR}/libftdipp1.pc.in ${CMAKE_BINARY_DIR}/libftdipp1.pc @ONLY) |
| 172 | install(FILES ${CMAKE_BINARY_DIR}/libftdi1.pc ${CMAKE_BINARY_DIR}/libftdipp1.pc |
| 173 | DESTINATION lib${LIB_SUFFIX}/pkgconfig) |
| 174 | |
| 175 | if (UNIX OR MINGW) |
| 176 | configure_file ( libftdi1-config.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config @ONLY ) |
| 177 | install ( PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config |
| 178 | DESTINATION bin ) |
| 179 | endif () |
| 180 | |
| 181 | # config script install path |
| 182 | if ( NOT DEFINED LIBFTDI_CMAKE_CONFIG_DIR ) |
| 183 | set ( LIBFTDI_CMAKE_CONFIG_DIR lib${LIB_SUFFIX}/cmake/libftdi1 ) |
| 184 | endif () |
| 185 | |
| 186 | set ( LIBFTDI_INCLUDE_DIR ${includedir} ) |
| 187 | set ( LIBFTDI_INCLUDE_DIRS ${LIBFTDI_INCLUDE_DIR} ) |
| 188 | set ( LIBFTDI_LIBRARY ftdi1 ) |
| 189 | set ( LIBFTDI_LIBRARIES ${LIBFTDI_LIBRARY} ) |
| 190 | list ( APPEND LIBFTDI_LIBRARIES ${LIBUSB_LIBRARIES} ) |
| 191 | set ( LIBFTDI_STATIC_LIBRARY ftdi1.a ) |
| 192 | set ( LIBFTDI_STATIC_LIBRARIES ${LIBFTDI_STATIC_LIBRARY} ) |
| 193 | list ( APPEND LIBFTDI_STATIC_LIBRARIES ${LIBUSB_LIBRARIES} ) |
| 194 | if (FTDI_BUILD_CPP) |
| 195 | set ( LIBFTDIPP_LIBRARY ftdipp1 ) |
| 196 | set ( LIBFTDIPP_LIBRARIES ${LIBFTDIPP_LIBRARY} ) |
| 197 | list ( APPEND LIBFTDIPP_LIBRARIES ${LIBUSB_LIBRARIES} ) |
| 198 | endif () |
| 199 | set ( LIBFTDI_LIBRARY_DIRS ${libdir} ) |
| 200 | set ( LIBFTDI_ROOT_DIR ${prefix} ) |
| 201 | set ( LIBFTDI_VERSION_STRING ${VERSION_STRING} ) |
| 202 | set ( LIBFTDI_VERSION_MAJOR ${MAJOR_VERSION} ) |
| 203 | set ( LIBFTDI_VERSION_MINOR ${MINOR_VERSION} ) |
| 204 | |
| 205 | set ( LIBFTDI_USE_FILE ${CMAKE_INSTALL_PREFIX}/${LIBFTDI_CMAKE_CONFIG_DIR}/UseLibFTDI1.cmake ) |
| 206 | |
| 207 | if(CMAKE_VERSION VERSION_LESS 2.8.8) |
| 208 | configure_file ( cmake/LibFTDI1Config.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake @ONLY ) |
| 209 | configure_file ( cmake/LibFTDI1ConfigVersion.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1ConfigVersion.cmake @ONLY ) |
| 210 | else () |
| 211 | include(CMakePackageConfigHelpers) |
| 212 | |
| 213 | configure_package_config_file ( |
| 214 | cmake/LibFTDI1Config.cmake.in |
| 215 | ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake |
| 216 | INSTALL_DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR} |
| 217 | PATH_VARS |
| 218 | LIBFTDI_USE_FILE |
| 219 | LIBFTDI_ROOT_DIR |
| 220 | LIBFTDI_INCLUDE_DIR |
| 221 | LIBFTDI_INCLUDE_DIRS |
| 222 | LIBFTDI_LIBRARY_DIRS |
| 223 | NO_CHECK_REQUIRED_COMPONENTS_MACRO |
| 224 | ) |
| 225 | write_basic_package_version_file ( |
| 226 | LibFTDI1ConfigVersion.cmake |
| 227 | VERSION ${LIBFTDI_VERSION_STRING} |
| 228 | COMPATIBILITY AnyNewerVersion |
| 229 | ) |
| 230 | endif () |
| 231 | |
| 232 | |
| 233 | install ( FILES |
| 234 | ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake |
| 235 | ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1ConfigVersion.cmake |
| 236 | cmake/UseLibFTDI1.cmake |
| 237 | |
| 238 | DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR} |
| 239 | ) |
| 240 | |
| 241 | |
| 242 | |
| 243 | |
| 244 | include(CPack) |