developer.intra2net.com Git - libi2ncommon/blob - CMakeLists.txt

   1 # Project
   2 project(libi2ncommon)
   3
   4 # Version settings
   5 set(VERSION 2.4)
   6
   7 SET(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}")
   8
   9 # CMake
  10 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  11    set(CMAKE_BUILD_TYPE     Debug)
  12 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  13 set(CMAKE_COLOR_MAKEFILE ON)
  14 cmake_minimum_required(VERSION 2.6 FATAL_ERROR)
  15
  16 # Debug build
  17 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  18 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  19    add_definitions(-DDEBUG)
  20 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  21
  22 # Enable all warnings
  23 add_definitions("-Wall")
  24
  25 # Set components
  26 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  27 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  28 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  29
  30 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  31 "Shared library for general use.")
  32 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  33 "C/C++ header files.")
  34
  35 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  36 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  37
  38 # Package information
  39 set(CPACK_PACKAGE_VERSION              ${VERSION})
  40 set(CPACK_PACKAGE_CONTACT              "Intra2net AG <libi2ncommon@developer.intra2net.com>")
  41 set(CPACK_PACKAGE_DESCRIPTION          "libi2ncommon library.")
  42 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION}
  43                                        )
  44 # Package settings
  45 set(CPACK_GENERATOR                    "DEB;RPM")
  46 set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
  47 set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
  48 set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})
  49
  50 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/COPYING.GPL)
  51
  52 set(CPACK_SOURCE_GENERATOR             TGZ)
  53 set(CPACK_SOURCE_IGNORE_FILES
  54     "~$"
  55     "\\\\.git"
  56     "build"
  57     "build-rpm"
  58 )
  59 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_FILE_NAME})
  60
  61 # "make dist" target
  62 set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION})
  63 add_custom_target(dist
  64     COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
  65             | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
  66     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
  67
  68 # documentation
  69 option(DOCUMENTATION "Generate API documentation with Doxygen" ON)
  70 find_package(Doxygen)
  71 if(DOCUMENTATION AND DOXYGEN_FOUND)
  72    # Set variables
  73    set(PACKAGE libi2ncommon)
  74    set(top_srcdir ${CMAKE_SOURCE_DIR})
  75
  76    # Find doxy config
  77    message(STATUS "Doxygen found.")
  78    set(DOXY_DIR "${CMAKE_SOURCE_DIR}/doc")
  79    set(DOXY_CONFIG "${DOXY_DIR}/Doxyfile.in")
  80
  81    # Copy doxy.config.in
  82    configure_file("${DOXY_CONFIG}" "${CMAKE_BINARY_DIR}/doxy.config")
  83
  84    # Create doc directory
  85    add_custom_command(
  86    OUTPUT ${CMAKE_BINARY_DIR}/doc
  87    COMMAND rm -rf ${CMAKE_BINARY_DIR}/doc/{html,man}
  88    COMMAND mkdir -p ${CMAKE_BINARY_DIR}/doc
  89    DEPENDS src configlib xmllib utils test
  90    )
  91
  92    # Run doxygen
  93    add_custom_command(
  94    OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html
  95    COMMAND ${DOXYGEN_EXECUTABLE} "${CMAKE_BINARY_DIR}/doxy.config"
  96    DEPENDS "${CMAKE_BINARY_DIR}/doxy.config" "${CMAKE_BINARY_DIR}/doc"
  97    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/doc
  98    )
  99
 100    add_custom_target(docs ALL DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html)
 101
 102    message(STATUS "Generating API documentation with Doxygen")
 103 else(DOCUMENTATION AND DOXYGEN_FOUND)
 104    message(STATUS "Not generating API documentation")
 105 endif(DOCUMENTATION AND DOXYGEN_FOUND)
 106
 107 # Conditional build itmes
 108 option(BUILD_XMLLIB "Build xml part of libi2ncommon - needs patched libxml++" OFF)
 109 if (BUILD_XMLLIB)
 110    message(STATUS "Build xml library part")
 111 else(BUILD_XMLLIB)
 112    message(STATUS "NOT building xml library part")
 113 endif(BUILD_XMLLIB)
 114
 115 option(IMAP_UTF7_SUPPORT "Enable imap modified utf7 support - needs patched libiconv" OFF)
 116 if (IMAP_UTF7_SUPPORT)
 117    message(STATUS "Build imap modified utf7 support")
 118 else(IMAP_UTF7_SUPPORT)
 119    message(STATUS "NOT building imap modified utf7 support")
 120 endif(IMAP_UTF7_SUPPORT)
 121
 122 # Find external packages
 123 include(FindPkgConfig)
 124
 125 # Find Boost
 126 find_package(Boost 1.44 COMPONENTS iostreams unit_test_framework thread REQUIRED)
 127
 128 # Find libxml++
 129 if (BUILD_XMLLIB)
 130     pkg_check_modules(XMLPP REQUIRED libxml++-2.6)
 131 endif(BUILD_XMLLIB)
 132
 133 # Find iconv
 134 if (IMAP_UTF7_SUPPORT)
 135     pkg_check_modules(ICONV REQUIRED libiconv)
 136     include_directories($ICONV_INCLUDE_DIRS})
 137     link_directories(${ICONV_LIBRARY_DIRS})
 138 endif(IMAP_UTF7_SUPPORT)
 139
 140 # pkgconfig output
 141 set(prefix      ${CMAKE_INSTALL_PREFIX})
 142 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 143 set(includedir  ${CMAKE_INSTALL_PREFIX}/include)
 144 set(libdir      ${CMAKE_INSTALL_PREFIX}/lib)
 145
 146 # construct ${BOOST_LDADD} from ${Boost_LIBRARIES}
 147 string(REGEX REPLACE ";" " " BOOST_LDADD "${Boost_IOSTREAMS_LIBRARIES}")
 148 set(BOOST_LDADD "${BOOST_LDADD}")
 149
 150 # construct ${BOOST_CFLAGS} from ${Boost_INCLUDE_DIRS}
 151 string(REGEX REPLACE ";" " -I" BOOST_CFLAGS "${Boost_INCLUDE_DIRS}")
 152 set(BOOST_CFLAGS "-I${BOOST_CFLAGS}")
 153
 154 # construct ${ICONV_CFLAGS} from ${ICONV_INCLUDE_DIRS}
 155 string(REGEX REPLACE ";" " -I" ICONV_CFLAGS "${ICONV_INCLUDE_DIRS}")
 156 set(ICONV_CFLAGS "-I${ICONV_CFLAGS}")
 157
 158 configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon.pc @ONLY)
 159 configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon_config.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon_config.pc @ONLY)
 160 configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon_utils.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon_utils.pc @ONLY)
 161
 162 install(FILES ${CMAKE_BINARY_DIR}/libi2ncommon.pc
 163                      ${CMAKE_BINARY_DIR}/libi2ncommon_config.pc
 164                      ${CMAKE_BINARY_DIR}/libi2ncommon_utils.pc
 165         DESTINATION lib/pkgconfig)
 166
 167 if (BUILD_XMLLIB)
 168     configure_file(${CMAKE_SOURCE_DIR}/libi2ncommon_xml.pc.in ${CMAKE_BINARY_DIR}/libi2ncommon_xml.pc @ONLY)
 169     install(FILES ${CMAKE_BINARY_DIR}/libi2ncommon_xml.pc DESTINATION lib/pkgconfig)
 170 endif(BUILD_XMLLIB)
 171
 172
 173 include(CPack)
 174
 175 # Subdirectories
 176 set(CPACK_SET_DESTDIR "ON")
 177
 178 add_subdirectory(src)
 179 add_subdirectory(configlib)
 180 add_subdirectory(utils)
 181 add_subdirectory(test)
 182 if (BUILD_XMLLIB)
 183     add_subdirectory(xmllib)
 184 endif(BUILD_XMLLIB)