.kdev4/
build/
-# Automake
-Makefile
-Makefile.in
-autom4te.cache
-aclocal.m4
-libtool
-stamp-h1
-configure
-config.*
-*.substvars
-ltmain.sh
-missing
-install-sh
-depcomp
-INSTALL
-
# kdevelop
*.kdevelop.pcs
*.kdevses
examples/serial_test
examples/simple
-# python bindings
-bindings/python/setup.py
-
# Backup files and stuff from patches
*.orig
*.rej
+++ /dev/null
-# not a GNU package. You can remove this line, if
-# have all needed files, that a GNU package needs
-AUTOMAKE_OPTIONS = foreign 1.4
-
-SUBDIRS = src bindings $(LIBFTDI_MODULES) examples doc
-
-EXTRA_DIST = libftdi.spec libftdi.spec.in COPYING.LIB COPYING.GPL LICENSE \
- README AUTHORS ChangeLog libftdi-config.in CMakeLists.txt \
- packages COPYING-CMAKE-SCRIPTS FindUSB.cmake README.mingw \
- Toolchain-mingw32.cmake Toolchain-Crossbuild32.cmake
-
-bin_SCRIPTS = libftdi-config
-
-# Install the pkg-config file:
-pkgconfigdir = $(libdir)/pkgconfig
-pkgconfig_DATA = libftdi.pc $(LIBFTDI_MODULES_PKGCONFIG)
-
-USB_LIBS = @USB_LIBS@
-
-ACLOCAL_AMFLAGS=-I m4
+++ /dev/null
-default: all
-
-all:
- autoreconf --install
+++ /dev/null
-# ===========================================================================
-# http://autoconf-archive.cryp.to/ax_boost_base.html
-# ===========================================================================
-#
-# SYNOPSIS
-#
-# AX_BOOST_BASE([MINIMUM-VERSION])
-#
-# DESCRIPTION
-#
-# Test for the Boost C++ libraries of a particular version (or newer)
-#
-# If no path to the installed boost library is given the macro searchs
-# under /usr, /usr/local, /opt and /opt/local and evaluates the
-# $BOOST_ROOT environment variable. Further documentation is available at
-# <http://randspringer.de/boost/index.html>.
-#
-# This macro calls:
-#
-# AC_SUBST(BOOST_CPPFLAGS) / AC_SUBST(BOOST_LDFLAGS)
-#
-# And sets:
-#
-# HAVE_BOOST
-#
-# LAST MODIFICATION
-#
-# 2008-04-12
-#
-# COPYLEFT
-#
-# Copyright (c) 2008 Thomas Porschberg <thomas@randspringer.de>
-#
-# Copying and distribution of this file, with or without modification, are
-# permitted in any medium without royalty provided the copyright notice
-# and this notice are preserved.
-
-AC_DEFUN([AX_BOOST_BASE],
-[
-AC_ARG_WITH([boost],
- AS_HELP_STRING([--with-boost@<:@=DIR@:>@], [use boost (default is yes) - it is possible to specify the root directory for boost (optional)]),
- [
- if test "$withval" = "no"; then
- want_boost="no"
- elif test "$withval" = "yes"; then
- want_boost="yes"
- ac_boost_path=""
- else
- want_boost="yes"
- ac_boost_path="$withval"
- fi
- ],
- [want_boost="yes"])
-
-
-AC_ARG_WITH([boost-libdir],
- AS_HELP_STRING([--with-boost-libdir=LIB_DIR],
- [Force given directory for boost libraries. Note that this will overwrite library path detection, so use this parameter only if default library detection fails and you know exactly where your boost libraries are located.]),
- [
- if test -d $withval
- then
- ac_boost_lib_path="$withval"
- else
- AC_MSG_ERROR(--with-boost-libdir expected directory name)
- fi
- ],
- [ac_boost_lib_path=""]
-)
-
-if test "x$want_boost" = "xyes"; then
- boost_lib_version_req=ifelse([$1], ,1.20.0,$1)
- boost_lib_version_req_shorten=`expr $boost_lib_version_req : '\([[0-9]]*\.[[0-9]]*\)'`
- boost_lib_version_req_major=`expr $boost_lib_version_req : '\([[0-9]]*\)'`
- boost_lib_version_req_minor=`expr $boost_lib_version_req : '[[0-9]]*\.\([[0-9]]*\)'`
- boost_lib_version_req_sub_minor=`expr $boost_lib_version_req : '[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\)'`
- if test "x$boost_lib_version_req_sub_minor" = "x" ; then
- boost_lib_version_req_sub_minor="0"
- fi
- WANT_BOOST_VERSION=`expr $boost_lib_version_req_major \* 100000 \+ $boost_lib_version_req_minor \* 100 \+ $boost_lib_version_req_sub_minor`
- AC_MSG_CHECKING(for boostlib >= $boost_lib_version_req)
- succeeded=no
-
- dnl first we check the system location for boost libraries
- dnl this location ist chosen if boost libraries are installed with the --layout=system option
- dnl or if you install boost with RPM
- if test "$ac_boost_path" != ""; then
- BOOST_LDFLAGS="-L$ac_boost_path/lib"
- BOOST_CPPFLAGS="-I$ac_boost_path/include"
- elif test "$cross_compiling" != yes; then
- for ac_boost_path_tmp in /usr /usr/local /opt /opt/local ; do
- if test -d "$ac_boost_path_tmp/include/boost" && test -r "$ac_boost_path_tmp/include/boost"; then
- BOOST_LDFLAGS="-L$ac_boost_path_tmp/lib"
- BOOST_CPPFLAGS="-I$ac_boost_path_tmp/include"
- break;
- fi
- done
- fi
-
- dnl overwrite ld flags if we have required special directory with
- dnl --with-boost-libdir parameter
- if test "$ac_boost_lib_path" != ""; then
- BOOST_LDFLAGS="-L$ac_boost_lib_path"
- fi
-
- CPPFLAGS_SAVED="$CPPFLAGS"
- CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
- export CPPFLAGS
-
- LDFLAGS_SAVED="$LDFLAGS"
- LDFLAGS="$LDFLAGS $BOOST_LDFLAGS"
- export LDFLAGS
-
- AC_LANG_PUSH(C++)
- AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
- @%:@include <boost/version.hpp>
- ]], [[
- #if BOOST_VERSION >= $WANT_BOOST_VERSION
- // Everything is okay
- #else
- # error Boost version is too old
- #endif
- ]])],[
- AC_MSG_RESULT(yes)
- succeeded=yes
- found_system=yes
- ],[
- ])
- AC_LANG_POP([C++])
-
-
-
- dnl if we found no boost with system layout we search for boost libraries
- dnl built and installed without the --layout=system option or for a staged(not installed) version
- if test "x$succeeded" != "xyes"; then
- _version=0
- if test "$ac_boost_path" != ""; then
- if test -d "$ac_boost_path" && test -r "$ac_boost_path"; then
- for i in `ls -d $ac_boost_path/include/boost-* 2>/dev/null`; do
- _version_tmp=`echo $i | sed "s#$ac_boost_path##" | sed 's/\/include\/boost-//' | sed 's/_/./'`
- V_CHECK=`expr $_version_tmp \> $_version`
- if test "$V_CHECK" = "1" ; then
- _version=$_version_tmp
- fi
- VERSION_UNDERSCORE=`echo $_version | sed 's/\./_/'`
- BOOST_CPPFLAGS="-I$ac_boost_path/include/boost-$VERSION_UNDERSCORE"
- done
- fi
- else
- if test "$cross_compiling" != yes; then
- for ac_boost_path in /usr /usr/local /opt /opt/local ; do
- if test -d "$ac_boost_path" && test -r "$ac_boost_path"; then
- for i in `ls -d $ac_boost_path/include/boost-* 2>/dev/null`; do
- _version_tmp=`echo $i | sed "s#$ac_boost_path##" | sed 's/\/include\/boost-//' | sed 's/_/./'`
- V_CHECK=`expr $_version_tmp \> $_version`
- if test "$V_CHECK" = "1" ; then
- _version=$_version_tmp
- best_path=$ac_boost_path
- fi
- done
- fi
- done
-
- VERSION_UNDERSCORE=`echo $_version | sed 's/\./_/'`
- BOOST_CPPFLAGS="-I$best_path/include/boost-$VERSION_UNDERSCORE"
- if test "$ac_boost_lib_path" = ""
- then
- BOOST_LDFLAGS="-L$best_path/lib"
- fi
-
- fi
-
- if test "x$BOOST_ROOT" != "x"; then
- if test -d "$BOOST_ROOT" && test -r "$BOOST_ROOT" && test -d "$BOOST_ROOT/stage/lib" && test -r "$BOOST_ROOT/stage/lib"; then
- version_dir=`expr //$BOOST_ROOT : '.*/\(.*\)'`
- stage_version=`echo $version_dir | sed 's/boost_//' | sed 's/_/./g'`
- stage_version_shorten=`expr $stage_version : '\([[0-9]]*\.[[0-9]]*\)'`
- V_CHECK=`expr $stage_version_shorten \>\= $_version`
- if test "$V_CHECK" = "1" -a "$ac_boost_lib_path" = "" ; then
- AC_MSG_NOTICE(We will use a staged boost library from $BOOST_ROOT)
- BOOST_CPPFLAGS="-I$BOOST_ROOT"
- BOOST_LDFLAGS="-L$BOOST_ROOT/stage/lib"
- fi
- fi
- fi
- fi
-
- CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
- export CPPFLAGS
- LDFLAGS="$LDFLAGS $BOOST_LDFLAGS"
- export LDFLAGS
-
- AC_LANG_PUSH(C++)
- AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
- @%:@include <boost/version.hpp>
- ]], [[
- #if BOOST_VERSION >= $WANT_BOOST_VERSION
- // Everything is okay
- #else
- # error Boost version is too old
- #endif
- ]])],[
- AC_MSG_RESULT(yes)
- succeeded=yes
- found_system=yes
- ],[
- ])
- AC_LANG_POP([C++])
- fi
-
- if test "$succeeded" != "yes" ; then
- if test "$_version" = "0" ; then
- AC_MSG_NOTICE([[We could not detect the boost libraries (version $boost_lib_version_req_shorten or higher). If you have a staged boost library (still not installed) please specify \$BOOST_ROOT in your environment and do not give a PATH to --with-boost option. If you are sure you have boost installed, then check your version number looking in <boost/version.hpp>. See http://randspringer.de/boost for more documentation.]])
- else
- AC_MSG_NOTICE([Your boost libraries seems to old (version $_version).])
- fi
- HAVE_BOOST=no
- else
- AC_SUBST(BOOST_CPPFLAGS)
- AC_SUBST(BOOST_LDFLAGS)
- AC_DEFINE(HAVE_BOOST,,[define if the Boost library is available])
- HAVE_BOOST=yes
- fi
-
- CPPFLAGS="$CPPFLAGS_SAVED"
- LDFLAGS="$LDFLAGS_SAVED"
-fi
-
-])
+++ /dev/null
-SUBDIRS = python
-
-EXTRA_DIST = ftdi.i CMakeLists.txt
+++ /dev/null
-
-## Process this file with automake to produce Makefile.in
-
-if HAVE_SWIG
-if HAVE_PYTHON
-if ENABLE_PYTHON_BINDING
-
-LIBFTDI_INTERFACE = $(top_srcdir)/src/ftdi.h
-SWIG_INTERFACE = ../ftdi.i
-
-BUILT_SOURCES = ftdi_wrap.c ftdi.py
-CLEANFILES = ftdi_wrap.c ftdi.py
-
-all-local: ftdi_wrap.c ftdi.py
- @case "`uname`" in \
- MINGW*) \
- $(PYTHON) setup.py build --compiler=mingw32 \
- ;; \
- *) \
- CPPFLAGS="$(CPPFLAGS)" $(PYTHON) setup.py build \
- ;; \
- esac;
-
-# python on MinGW/MSYS requires pure Windows style paths
-# Using following (cd $dir && pwd -W) hack to get a nearly
-# native Windows path, then translating the forward slash
-# to a backward slash to make python distutils jolly.
-# P.S. the backslash has to be escaped thrice, hence a single
-# backslash turns into a sequence of eight (neat, huh?)
-#
-install-exec-local:
- @case "`uname`" in \
- MINGW*) \
- NATIVE_WINDOWS_PREFIX="`cd $(DESTDIR)$(prefix) && pwd -W`"; \
- NATIVE_WINDOWS_PREFIX="`echo $$NATIVE_WINDOWS_PREFIX | sed -e 's|/|\\\\\\\\|g'`"; \
- $(PYTHON) setup.py install --prefix="$$NATIVE_WINDOWS_PREFIX" \
- ;; \
- *) \
- CPPFLAGS="$(CPPFLAGS)" $(PYTHON) setup.py install --prefix=$(DESTDIR)$(prefix) \
- ;; \
- esac;
-
-# This rule cleans up stuff installed by Python's setup.py
-# Unfortunately, Python's distutils do not provide an uninstall
-# command, so we have to make up for it here in uninstall-local
-# hook. This might break if distutils' behaviour changes as automake
-# has no control over what distutils install command does.
-#
-uninstall-local:
- rm -rf $(DESTDIR)$(libdir)/python*/site-packages/*ftdi*
-
-clean-local:
- $(PYTHON) setup.py clean --all
-
-ftdi_wrap.c ftdi.py: $(SWIG_INTERFACE) $(LIBFTDI_INTERFACE)
- $(SWIG) -python -I$(top_srcdir)/src -o ftdi_wrap.c -outdir . $(srcdir)/$(SWIG_INTERFACE)
-
-
-endif # ENABLE_PYTHON_BINDING
-endif # HAVE_PYTHON
-endif # HAVE_SWIG
+++ /dev/null
-# Process this file with configure to produce setup.py
-
-from distutils.core import setup, Extension
-setup(name='@PACKAGE_NAME@',
- version='@PACKAGE_VERSION@',
- description='libftdi Python binding',
- author='Tarek Heiland',
- author_email='@PACKAGE_BUGREPORT@',
- maintainer='',
- maintainer_email='@PACKAGE_BUGREPORT@',
- url='',
- py_modules=['ftdi'],
- ext_modules=[Extension('_ftdi', ['ftdi_wrap.c'],
- include_dirs=['@top_srcdir@/src'],
- library_dirs=['@top_builddir@/src/.libs','lib','/usr/lib'],
- libraries=['ftdi'])],
- )
+++ /dev/null
-AC_INIT(libftdi, 0.17)
-AM_INIT_AUTOMAKE
-AM_CONFIG_HEADER(config.h)
-
-AC_LANG_C
-AC_PROG_CC
-AM_PROG_LIBTOOL
-AC_PROG_CXX
-
-AC_CONFIG_MACRO_DIR([m4])
-
-dnl check for libusb-1.0
-have_libusb_1_0=no
-PKG_CHECK_MODULES(LIBUSB_1_0, [ libusb-1.0 >= 1.0.0 ], have_libusb_1_0=yes, have_libusb_1_0=no)
-if test "$have_libusb_1_0" = "yes"; then
- CFLAGS="$CFLAGS $LIBUSB_1_0_CFLAGS"
- CXXFLAGS="$CXXFLAGS $LIBUSB_1_0_CFLAGS"
- USB_LIBS="$USB_LIBS $LIBUSB_1_0_LIBS"
- HAVE_USB=yes
- AC_DEFINE(HAVE_LIBUSB_1_0, 1, [Define to 1 if you have libusb-1.0.])
- AC_SUBST(USB_LIBS)
-else
- AC_MSG_ERROR([libusb-1.0 not found.])
-fi
-
-AC_ARG_WITH(examples,
- AS_HELP_STRING([--without-examples], [disable example programs]))
-AM_CONDITIONAL(BUILD_EXAMPLES, [test "x$with_examples" != "xno"])
-
-LIBFTDI_MODULES=
-LIBFTDI_MODULES_PKGCONFIG=
-
-dnl libftdi C++ wrapper. Needs boost.
-AX_BOOST_BASE([1.33])
-ENABLE_LIBFTDIPP=0
-AC_MSG_CHECKING(if we can build the C++ wrapper)
-AC_ARG_ENABLE(libftdipp,
- AS_HELP_STRING([--enable-libftdipp],
- [enable libftdi C++ wrapper. Needs boost (default: auto)]),
-[
- if test "$enableval" != "no"; then
- if test "x$HAVE_BOOST" != "xyes"; then
- AC_MSG_ERROR(Sorry, we need the boost library for the C++ wrapper)
- fi
- ENABLE_LIBFTDIPP=1
- fi
-],
-[
- dnl Build the wrapper if we got the boost library
- if test "x$HAVE_BOOST" = "xyes"; then
- ENABLE_LIBFTDIPP=1
- fi
-])
-if test "x$ENABLE_LIBFTDIPP" = "x1"; then
- LIBFTDI_MODULES="$LIBFTDI_MODULES ftdipp"
- LIBFTDI_MODULES_PKGCONFIG="$LIBFTDI_MODULES_PKGCONFIG libftdipp.pc"
- AC_MSG_RESULT(yes)
-else
- AC_MSG_RESULT(no)
-fi
-AM_CONDITIONAL(HAVE_LIBFTDIPP, [test "x$ENABLE_LIBFTDIPP" = "x1"])
-
-dnl check for doxygen
-AC_ARG_WITH(docs,
- AS_HELP_STRING([--without-docs], [disable doxygen usage]))
-if test "x$with_docs" != "xno"; then
- AC_PATH_PROG(DOXYGEN, doxygen)
-else
- DOXYGEN=
-fi
-AM_CONDITIONAL(HAVE_DOXYGEN, test -n $DOXYGEN)
-
-dnl ============================
-dnl Bindings for other languages
-dnl ==
-
-dnl ===============
-dnl Checks for SWIG
-dnl ===============
-AC_PATH_PROG([SWIG], [swig])
-AM_CONDITIONAL(HAVE_SWIG, test "$SWIG")
-
-dnl =================
-dnl Checks for Python
-dnl =================
-AM_PATH_PYTHON([2.0],
- [],
- [AC_MSG_WARN([Python not found. Python is required to build presage python binding. Python can be obtained from http://www.pyth
-on.org])])
-if test "$PYTHON"
-then
- python_include_path=`$PYTHON -c "import distutils.sysconfig; print distutils.sysconfig.get_python_inc();"`
- AC_CHECK_HEADERS([${python_include_path}/Python.h],
- [have_python_header=true],
- [AC_MSG_WARN([Python.h header file not found. Python development files are required to build presage python binding. Pyt
-hon can be obtained from http://www.python.org])],
- [])
-fi
-AM_CONDITIONAL(HAVE_PYTHON, test "$PYTHON" -a "x$have_python_header" = "xtrue")
-
-AC_ARG_ENABLE([python-binding],
- AS_HELP_STRING([--enable-python-binding],
- [build python binding (default=no)]),
- [ac_enable_python_binding=$enableval],
- [ac_enable_python_binding=no])
-if test "x$ac_enable_python_binding" = "xyes"
-then
- if test ! "$SWIG" -o ! "$PYTHON" -o ! "x$have_python_header" = "xtrue"
- then
- AC_MSG_WARN([Python binding for libftdi cannot be built. Ensure that SWIG and Python packages are available.])
- fi
-else
- AC_MSG_NOTICE([Python binding for libftdi will not be built.])
- AC_MSG_NOTICE([Enable Python binding module building with --enable-python-binding])
-fi
-AM_CONDITIONAL(ENABLE_PYTHON_BINDING, test "x$ac_enable_python_binding" = "xyes")
-
-if test "$SWIG" -a "$PYTHON" -a "x$have_python_header" = "xtrue" -a "x$ac_enable_python_binding" = "xyes"
-then
- AC_MSG_NOTICE([Python binding for libftdi will be built.])
- build_python_binding="yes"
-else
- build_python_binding="no"
-fi
-
-AC_SUBST(LIBFTDI_MODULES)
-AC_SUBST(LIBFTDI_MODULES_PKGCONFIG)
-
-AC_CONFIG_FILES([libftdi-config],[chmod a+x libftdi-config])
-AC_CONFIG_FILES(Makefile src/Makefile bindings/Makefile bindings/python/Makefile bindings/python/setup.py examples/Makefile doc/Doxyfile doc/Makefile libftdi.pc libftdi.spec)
-
-if test "x$ENABLE_LIBFTDIPP" = "x1"; then
- AC_CONFIG_FILES(ftdipp/Makefile libftdipp.pc)
-fi
-
-AC_OUTPUT
+++ /dev/null
-CLEANFILES = rm -rf html man
-
-if HAVE_DOXYGEN
-MANUALS = html/index.html
-else
-MANUALS =
-endif
-
-all: $(MANUALS)
-
-html/index.html: $(top_srcdir)/src/*.c $(top_srcdir)/src/*.h $(top_srcdir)/ftdipp/*.cpp $(top_srcdir)/ftdipp/*.hpp $(top_srcdir)/examples/*.c
- $(DOXYGEN)
+++ /dev/null
-METASOURCES = AUTO
-INCLUDES = -I$(top_srcdir)/src -I$(top_srcdir)/ftdipp
-LDADD = $(top_builddir)/src/libftdi.la
-
-
-if HAVE_LIBFTDIPP
-examples_libftdipp = find_all_pp
-else
-examples_libftdipp =
-endif
-
-
-if BUILD_EXAMPLES
-all_examples = simple \
- bitbang \
- bitbang2 \
- bitbang_ft2232 \
- bitbang_cbus \
- find_all \
- serial_test \
- baud_test \
- $(examples_libftdipp)
-else
-all_examples =
-endif
-bin_PROGRAMS = $(all_examples)
-
-# Don't install the example files
-AM_LDFLAGS = -no-install
-
-simple_SOURCES = simple.c
-bitbang_SOURCES = bitbang.c
-bitbang2_SOURCES = bitbang2.c
-bitbang_ft2232_SOURCES = bitbang_ft2232.c
-bitbang_cbus_SOURCES = bitbang_cbus.c
-find_all_SOURCES = find_all.c
-serial_test_SOURCES = serial_test.c
-baud_test_SOURCES = baud_test.c
-
-if HAVE_LIBFTDIPP
-find_all_pp_SOURCES = find_all_pp.cpp
-find_all_pp_LDADD = $(top_builddir)/ftdipp/libftdipp.la $(LDADD)
-endif
-
-EXTRA_DIST = CMakeLists.txt
+++ /dev/null
-# set the include path found by configure
-INCLUDES= -I$(top_srcdir)/src @BOOST_CPPFLAGS@
-
-# the library search path.
-lib_LTLIBRARIES = libftdipp.la
-include_HEADERS = ftdi.hpp
-libftdipp_la_SOURCES = ftdi.cpp
-
-# Note: If you specify a:b:c as the version in the next line,
-# the library that is made has version (a-c).c.b. In this
-# example, the version is 2.1.2. (3:2:1)
-libftdipp_la_LDFLAGS = -version-info 18:0:17 @BOOST_LDFLAGS@
-libftdipp_la_LIBADD = $(top_builddir)/src/libftdi.la
-
-EXTRA_DIST = CMakeLists.txt
+++ /dev/null
-# the library search path.
-lib_LTLIBRARIES = libftdi.la
-libftdi_la_SOURCES = ftdi.c ftdi_stream.c
-include_HEADERS = ftdi.h
-
-# Note: If you specify a:b:c as the version in the next line,
-# the library that is made has version (a-c).c.b. In this
-# example, the version is 2.1.2. (3:2:1)
-libftdi_la_LDFLAGS = -version-info 18:0:17
-libftdi_la_LIBADD = @USB_LIBS@
-
-EXTRA_DIST = CMakeLists.txt
git://developer.intra2net.com / libftdi / commitdiff