developer.intra2net.com Git - libftdi/blob - CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.15 FATAL_ERROR)
   2
   3 message(STATUS "CMake version: ${CMAKE_VERSION}")
   4
   5 # Project
   6 project(libftdi1 C)
   7 set(MAJOR_VERSION 1)
   8 set(MINOR_VERSION 6)
   9 set(PACKAGE libftdi1)
  10 set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION}rc1)
  11 set(VERSION ${VERSION_STRING})
  12 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  13
  14 # Target link properties INTERFACE_LINK_OPTIONS, INTERFACE_LINK_DIRECTORIES
  15 # and INTERFACE_LINK_DEPENDS are now transitive over private dependencies
  16 # of static libraries
  17 if (POLICY CMP0099)
  18     cmake_policy(SET CMP0099 NEW)
  19 endif ()
  20
  21 # CMake
  22 if ("${CMAKE_BUILD_TYPE}" STREQUAL "")
  23     set(CMAKE_BUILD_TYPE RelWithDebInfo)
  24 endif ("${CMAKE_BUILD_TYPE}" STREQUAL "")
  25
  26 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  27
  28 if (NOT PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR)
  29     # Auto-create a .gitignore in the out-of-source build directory.
  30     file(GENERATE OUTPUT .gitignore CONTENT "*")
  31 endif ()
  32
  33 include(GNUInstallDirs)
  34
  35 add_definitions(-Wall)
  36
  37 include(CMakeOptions.txt)
  38
  39 # Debug build
  40 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  41 if (${CMAKE_BUILD_TYPE} STREQUAL Debug)
  42     add_definitions(-DDEBUG)
  43 endif (${CMAKE_BUILD_TYPE} STREQUAL Debug)
  44
  45 # Find libusb
  46 find_package(LibUSB REQUIRED)
  47 include_directories(${LIBUSB_INCLUDE_DIR})
  48
  49 # Set components
  50 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  51 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  52 set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries")
  53 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  54
  55 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  56         "Shared library for general use.")
  57 set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION
  58         "Static library, good if you want to embed libftdi1 in your application.")
  59 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  60         "C/C++ header files.")
  61
  62 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  63 set(CPACK_COMPONENT_STATICLIBS_GROUP "Development")
  64 set(CPACK_COMPONENT_HEADERS_GROUP "Development")
  65
  66 # guess LIB_SUFFIX, don't take debian multiarch into account
  67 if (NOT DEFINED LIB_SUFFIX)
  68     if (CMAKE_SYSTEM_NAME MATCHES "Linux"
  69             AND NOT CMAKE_CROSSCOMPILING
  70             AND NOT EXISTS "/etc/debian_version"
  71             AND NOT EXISTS "/etc/arch-release")
  72         if ("${CMAKE_SIZEOF_VOID_P}" EQUAL "8")
  73             set(LIB_SUFFIX 64)
  74         endif ()
  75     endif ()
  76 endif ()
  77
  78 if (NOT APPLE)
  79     if (CMAKE_SIZEOF_VOID_P EQUAL 4)
  80         SET(PACK_ARCH "")
  81     elseif (CMAKE_SIZEOF_VOID_P EQUAL 8)
  82         SET(PACK_ARCH .x86_64)
  83     endif (CMAKE_SIZEOF_VOID_P EQUAL 4)
  84 else (NOT APPLE)
  85     SET(PACK_ARCH "")
  86 endif (NOT APPLE)
  87
  88 # Package information
  89 set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
  90 set(CPACK_PACKAGE_CONTACT "Intra2net AG <libftdi@developer.intra2net.com>")
  91 set(CPACK_PACKAGE_DESCRIPTION "libftdi1 library.")
  92 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY ${CPACK_PACKAGE_DESCRIPTION})
  93
  94 # Package settings
  95 if (UNIX)
  96     set(CPACK_GENERATOR "DEB;RPM")
  97     set(CPACK_CMAKE_GENERATOR "Unix Makefiles")
  98     set(CPACK_PACKAGE_NAME ${PROJECT_NAME})
  99     set(CPACK_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})
 100 endif ()
 101
 102 if (WIN32)
 103     set(CPACK_GENERATOR "NSIS")
 104     set(CPACK_CMAKE_GENERATOR "MinGW Makefiles")
 105     set(CPACK_PACKAGE_NAME "${PROJECT_NAME}")
 106     set(CPACK_PACKAGE_VENDOR "")
 107     set(CPACK_PACKAGE_INSTALL_DIRECTORY "libftdi1")
 108     set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
 109     set(CPACK_NSIS_DISPLAY_NAME "libftdi1")
 110     set(CPACK_NSIS_MODIFY_PATH ON)
 111 endif ()
 112
 113 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 114
 115 set(CPACK_SOURCE_GENERATOR TGZ)
 116 set(CPACK_SOURCE_IGNORE_FILES "\\\\.git;~$;build/")
 117 set(CPACK_SOURCE_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION})
 118
 119 # Subdirectories
 120 if (UNIX)
 121     set(CPACK_SET_DESTDIR ON)
 122 endif ()
 123
 124 # "make dist" target
 125 set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION_STRING})
 126 add_custom_target(dist
 127         COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
 128         | bzip2 > ${PROJECT_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
 129         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
 130
 131 add_subdirectory(src)
 132 add_subdirectory(packages)
 133
 134 if (DOCUMENTATION)
 135     add_subdirectory(doc)
 136 endif (DOCUMENTATION)
 137
 138 if (FTDIPP)
 139     project(libftdi1 C CXX)
 140     add_subdirectory(ftdipp)
 141 endif (FTDIPP)
 142
 143 if (PYTHON_BINDINGS)
 144     add_subdirectory(python)
 145 endif (PYTHON_BINDINGS)
 146
 147 if (FTDI_EEPROM)
 148     add_subdirectory(ftdi_eeprom)
 149 endif (FTDI_EEPROM)
 150
 151 if (EXAMPLES)
 152     add_subdirectory(examples)
 153 endif (EXAMPLES)
 154
 155 if (BUILD_TESTS)
 156     project(libftdi1 C CXX)
 157     add_subdirectory(test)
 158 endif (BUILD_TESTS)
 159
 160 # PkgConfig
 161 set(prefix ${CMAKE_INSTALL_PREFIX})
 162 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 163 set(includedir ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 164
 165 if (${UNIX})
 166     set(libdir ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR})
 167 endif (${UNIX})
 168 if (${WIN32})
 169     set(libdir ${CMAKE_INSTALL_PREFIX}/bin)
 170     if (STATICLIBS)
 171         list(APPEND libdir ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR})
 172     endif ()
 173 endif (${WIN32})
 174
 175 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libftdi1.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1.pc @ONLY)
 176 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libftdipp1.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libftdipp1.pc @ONLY)
 177 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libftdi1.pc ${CMAKE_CURRENT_BINARY_DIR}/libftdipp1.pc
 178         DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 179
 180 if (UNIX OR MINGW)
 181     configure_file(libftdi1-config.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config @ONLY)
 182     install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config
 183             DESTINATION bin)
 184 endif ()
 185
 186 # config script install path
 187 if (NOT DEFINED LIBFTDI_CMAKE_CONFIG_DIR)
 188     set(LIBFTDI_CMAKE_CONFIG_DIR ${CMAKE_INSTALL_LIBDIR}/cmake/libftdi1)
 189 endif ()
 190
 191 set(LIBFTDI_INCLUDE_DIR ${includedir})
 192 set(LIBFTDI_INCLUDE_DIRS ${LIBFTDI_INCLUDE_DIR})
 193
 194 # Set up library variables based on what's being built
 195 if (SHAREDLIBS)
 196     set(LIBFTDI_LIBRARY ftdi1)
 197     set(LIBFTDI_LIBRARIES ${LIBFTDI_LIBRARY})
 198     list(APPEND LIBFTDI_LIBRARIES ${LIBUSB_LIBRARIES})
 199 endif ()
 200
 201 if (STATICLIBS)
 202     set(LIBFTDI_STATIC_LIBRARY ftdi1.a)
 203     set(LIBFTDI_STATIC_LIBRARIES ${LIBFTDI_STATIC_LIBRARY})
 204     list(APPEND LIBFTDI_STATIC_LIBRARIES ${LIBUSB_LIBRARIES})
 205 endif ()
 206
 207 if (FTDIPP)
 208     if (SHAREDLIBS)
 209         set(LIBFTDIPP_LIBRARY ftdipp1)
 210         set(LIBFTDIPP_LIBRARIES ${LIBFTDIPP_LIBRARY})
 211         list(APPEND LIBFTDIPP_LIBRARIES ${LIBUSB_LIBRARIES})
 212     endif ()
 213     if (STATICLIBS)
 214         set(LIBFTDIPP_STATIC_LIBRARY ftdipp1.a)
 215         set(LIBFTDIPP_STATIC_LIBRARIES ${LIBFTDIPP_STATIC_LIBRARY})
 216         list(APPEND LIBFTDIPP_STATIC_LIBRARIES ${LIBUSB_LIBRARIES})
 217     endif ()
 218 endif ()
 219
 220 set(LIBFTDI_LIBRARY_DIRS ${libdir})
 221 set(LIBFTDI_ROOT_DIR ${prefix})
 222 set(LIBFTDI_VERSION_STRING ${VERSION_STRING})
 223 set(LIBFTDI_VERSION_MAJOR ${MAJOR_VERSION})
 224 set(LIBFTDI_VERSION_MINOR ${MINOR_VERSION})
 225
 226 set(LIBFTDI_USE_FILE ${CMAKE_INSTALL_PREFIX}/${LIBFTDI_CMAKE_CONFIG_DIR}/UseLibFTDI1.cmake)
 227
 228 include(CMakePackageConfigHelpers)
 229
 230 configure_package_config_file(
 231         cmake/LibFTDI1Config.cmake.in
 232         ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake
 233         INSTALL_DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR}
 234         PATH_VARS
 235         LIBFTDI_USE_FILE
 236         LIBFTDI_ROOT_DIR
 237         LIBFTDI_INCLUDE_DIR
 238         LIBFTDI_INCLUDE_DIRS
 239         LIBFTDI_LIBRARY_DIRS
 240         NO_CHECK_REQUIRED_COMPONENTS_MACRO
 241 )
 242 write_basic_package_version_file(
 243         LibFTDI1ConfigVersion.cmake
 244         VERSION ${LIBFTDI_VERSION_STRING}
 245         COMPATIBILITY AnyNewerVersion
 246 )
 247
 248 install(
 249         FILES
 250         ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake
 251         ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1ConfigVersion.cmake
 252         cmake/UseLibFTDI1.cmake
 253         DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR}
 254 )
 255
 256 include(CPack)
 257
 258 message(STATUS "Summary of build options:
 259
 260   Build shared libs: ${SHAREDLIBS}
 261   Build static libs: ${STATICLIBS}
 262   Build C++ bindings: ${FTDIPP}
 263   Build Python bindings: ${PYTHON_BINDINGS}
 264   Build ftdi_eeprom: ${FTDI_EEPROM}
 265   Build examples: ${EXAMPLES}
 266   Build tests: ${BUILD_TESTS}
 267   Build API documentation: ${DOCUMENTATION}
 268 ")