Reenabled all compile flags.

[libasyncio] / configure.in

AC_INIT(libasyncio, 0.2)
AC_PREREQ([2.50])
AM_INIT_AUTOMAKE
AM_CONFIG_HEADER(asyncio_config.hpp)

AC_CONFIG_FILES(Makefile asyncio/Makefile asyncio/libasyncio.pc doc/Doxyfile
        utils/libasyncio_utils.pc
        doc/Makefile glue_t2n/Makefile glue_t2n/libasyncio_t2n.pc unittest/Makefile utils/Makefile
        libasyncio.spec
        )


LIBASYNCIO_LIB_VERSION=0:0:0

AC_SUBST(LIBASYNCIO_LIB_VERSION)

AC_LANG_CPLUSPLUS
AC_PROG_CXX
AM_PROG_LIBTOOL


AC_ARG_WITH(optimize,
AS_HELP_STRING([--with-optimize],[compile with optimizing]),
[
    AC_MSG_CHECKING(for optimizing)
    if test "$withval" != "no"; then
        CXXFLAGS=" -g -O2 "
        AC_MSG_RESULT(yes)
    else
        CXXFLAGS=" -g -O0 "
        AC_MSG_RESULT(no)
    fi
],[ CXXFLAGS=" -g -O0 "])

dnl check for doxygen
AC_PATH_PROG(DOXYGEN, doxygen)
AM_CONDITIONAL(HAVE_DOXYGEN, test -n $DOXYGEN)

dnl check for libraries:

PKG_CHECK_MODULES(LIBI2NCOMMON, libi2ncommon,
[have_i2ncommon=yes
  AC_DEFINE([HAVE_LIBI2NCOMMON],,[define if libi2ncommon is available])
],
[have_i2ncommon=no
  AC_MSG_NOTICE([building without libi2ncommon support])
])
AM_CONDITIONAL([HAVE_LIBI2NCOMMON],[test x$have_i2ncommon = xyes])

AX_BOOST_BASE([1.34])
AX_BOOST_SIGNALS
AX_BOOST_UNIT_TEST_FRAMEWORK
if test "x$BOOST_SIGNALS_LIB" = "x"; then
    AC_MSG_ERROR([Sorry, we need the Signals-Lib from Boost.])
fi
if test "x$BOOST_UNIT_TEST_FRAMEWORK_LIB" = "x"; then
    AC_MSG_ERROR([Sorry, we need the unit test framework from Boost.])
fi

LIBT2N_CHECK(libt2n,[
  have_libt2n=yes
  AC_DEFINE([HAVE_LIBT2N],,[define if libt2n is available])
],[
  have_libt2n=no
  AC_MSG_NOTICE([Building without libt2n support])
])
AM_CONDITIONAL([HAVE_LIBT2N],[test x$have_libt2n = xyes])


dnl
dnl spit out the result files:

AC_OUTPUT