developer.intra2net.com Git - libftdi/blob - python/CMakeLists.txt

   1 option ( PYTHON_BINDINGS "Build python bindings via swig" ON )
   2 option ( LINK_PYTHON_LIBRARY "Link against python libraries" ON )
   3
   4 if ( PYTHON_BINDINGS )
   5   find_package ( SWIG )
   6   find_package ( PythonLibs )
   7   find_package ( PythonInterp )
   8 endif ()
   9
  10 if ( SWIG_FOUND AND PYTHONLIBS_FOUND AND PYTHONINTERP_FOUND )
  11   include ( UseSWIG )
  12   include_directories ( BEFORE ${CMAKE_SOURCE_DIR}/src )
  13   include_directories ( ${PYTHON_INCLUDE_DIRS} )
  14   link_directories ( ${CMAKE_CURRENT_BINARY_DIR}/../src )
  15
  16   swig_add_module ( ftdi1 python ftdi1.i )
  17   swig_link_libraries ( ftdi1 ftdi1 )
  18
  19   if ( LINK_PYTHON_LIBRARY )
  20     swig_link_libraries ( ftdi1 ${PYTHON_LIBRARIES} )
  21   endif ()
  22
  23   set_target_properties ( ${SWIG_MODULE_ftdi1_REAL_NAME} PROPERTIES NO_SONAME ON )
  24
  25   execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; print( sysconfig.get_python_lib( plat_specific=True, prefix='${CMAKE_INSTALL_PREFIX}' ) )"
  26                     OUTPUT_VARIABLE _ABS_PYTHON_MODULE_PATH
  27                     OUTPUT_STRIP_TRAILING_WHITESPACE )
  28
  29   get_filename_component ( _ABS_PYTHON_MODULE_PATH ${_ABS_PYTHON_MODULE_PATH} ABSOLUTE )
  30   file ( RELATIVE_PATH _REL_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX} ${_ABS_PYTHON_MODULE_PATH} )
  31
  32   set ( PYTHON_MODULE_PATH
  33         ${_REL_PYTHON_MODULE_PATH}
  34       )
  35
  36   INSTALL ( FILES ${CMAKE_CURRENT_BINARY_DIR}/_ftdi1.so DESTINATION ${PYTHON_MODULE_PATH} )
  37   INSTALL ( FILES ${CMAKE_CURRENT_BINARY_DIR}/ftdi1.py DESTINATION ${PYTHON_MODULE_PATH} )
  38
  39   if ( DOCUMENTATION AND DOXYGEN_FOUND )
  40
  41       set(CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
  42
  43       # Run doxygen to only generate the xml
  44       add_custom_command ( OUTPUT ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  45           COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc
  46           COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile.xml
  47           WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  48           DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers}
  49       )
  50
  51       # generate .i from doxygen .xml
  52       add_custom_command ( OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  53           COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
  54               ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  55               ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  56           DEPENDS ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  57       )
  58       add_custom_target ( doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i )
  59       add_dependencies( ${SWIG_MODULE_ftdi1_REAL_NAME} doc_i )
  60
  61   endif ()
  62
  63   set ( LIBFTDI_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX}/${PYTHON_MODULE_PATH} )
  64   set ( LIBFTDI_PYTHON_MODULE_PATH ${LIBFTDI_PYTHON_MODULE_PATH} PARENT_SCOPE ) # for ftdiconfig.cmake
  65   message(STATUS "Building python bindings via swig. Will be installed under ${LIBFTDI_PYTHON_MODULE_PATH}")
  66
  67   add_subdirectory ( examples )
  68 else ()
  69   message(STATUS "Not building python bindings")
  70 endif ()