developer.intra2net.com Git - libftdi/blob - python/CMakeLists.txt

   1 # swig_add_library behavior changed in cmake 3.13 to no longer set
   2 # SWIG_MODULE_<target>_REAL_NAME, so restore the old behavior.
   3 if ( POLICY CMP0078 )
   4   cmake_policy( SET CMP0078 OLD )
   5 endif ()
   6
   7 # workaround for cmake bug #0013449
   8 if ( NOT DEFINED CMAKE_FIND_ROOT_PATH OR NOT CMAKE_VERSION VERSION_LESS 3.0.0 )
   9   find_package ( SWIG REQUIRED )
  10 else ()
  11   find_program ( SWIG_EXECUTABLE NAMES swig2.0 swig )
  12   if ( SWIG_EXECUTABLE )
  13     set ( SWIG_USE_FILE ${CMAKE_ROOT}/Modules/UseSWIG.cmake )
  14     set ( SWIG_FOUND TRUE )
  15   endif ()
  16 endif ()
  17 find_package ( PythonLibs REQUIRED )
  18 find_package ( PythonInterp REQUIRED )
  19
  20 include ( UseSWIG )
  21 include_directories ( BEFORE ${CMAKE_SOURCE_DIR}/src )
  22 include_directories ( ${PYTHON_INCLUDE_DIRS} )
  23 link_directories ( ${CMAKE_CURRENT_BINARY_DIR}/../src )
  24
  25 if ( DOCUMENTATION )
  26   set(CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
  27 endif()
  28 if(NOT CMAKE_VERSION VERSION_LESS 3.8.0)
  29   swig_add_library ( ftdi1 LANGUAGE python SOURCES ftdi1.i )
  30 else ()
  31   swig_add_module ( ftdi1 python ftdi1.i )
  32 endif()
  33 swig_link_libraries ( ftdi1 ftdi1 )
  34
  35 if ( LINK_PYTHON_LIBRARY )
  36   swig_link_libraries ( ftdi1 ${PYTHON_LIBRARIES} )
  37 elseif( APPLE )
  38   set_target_properties ( ${SWIG_MODULE_ftdi1_REAL_NAME} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup" )
  39 endif ()
  40
  41 set_target_properties ( ${SWIG_MODULE_ftdi1_REAL_NAME} PROPERTIES NO_SONAME ON )
  42
  43 execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; print( sysconfig.get_python_lib( plat_specific=True, prefix='${CMAKE_INSTALL_PREFIX}' ) )"
  44                   OUTPUT_VARIABLE _ABS_PYTHON_MODULE_PATH
  45                   OUTPUT_STRIP_TRAILING_WHITESPACE )
  46
  47 get_filename_component ( _ABS_PYTHON_MODULE_PATH ${_ABS_PYTHON_MODULE_PATH} ABSOLUTE )
  48 file ( RELATIVE_PATH _REL_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX} ${_ABS_PYTHON_MODULE_PATH} )
  49
  50 set ( PYTHON_MODULE_PATH ${_REL_PYTHON_MODULE_PATH} )
  51
  52 install ( FILES ${CMAKE_CURRENT_BINARY_DIR}/ftdi1.py DESTINATION ${PYTHON_MODULE_PATH} )
  53 install ( TARGETS ${SWIG_MODULE_ftdi1_REAL_NAME} LIBRARY DESTINATION ${PYTHON_MODULE_PATH} )
  54
  55 if ( DOCUMENTATION )
  56     # Run doxygen to only generate the xml
  57     add_custom_command ( OUTPUT ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  58         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc
  59         COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile.xml
  60         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  61         DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers}
  62     )
  63
  64     # generate .i from doxygen .xml
  65     add_custom_command ( OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  66         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
  67             ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  68             ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  69         DEPENDS ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  70     )
  71     add_custom_target ( doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i )
  72     add_dependencies( ${SWIG_MODULE_ftdi1_REAL_NAME} doc_i )
  73
  74 endif ()
  75
  76 set ( LIBFTDI_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX}/${PYTHON_MODULE_PATH} )
  77 set ( LIBFTDI_PYTHON_MODULE_PATH ${LIBFTDI_PYTHON_MODULE_PATH} PARENT_SCOPE ) # for ftdiconfig.cmake
  78
  79 add_subdirectory ( examples )