developer.intra2net.com Git - libftdi/blob - python/CMakeLists.txt

   1 option ( PYTHON_BINDINGS "Build python bindings via swig" ON )
   2 option ( LINK_PYTHON_LIBRARY "Link against python libraries" ON )
   3
   4 if ( PYTHON_BINDINGS )
   5   # workaround for cmake bug #0013449
   6   if ( NOT DEFINED CMAKE_FIND_ROOT_PATH )
   7     find_package ( SWIG )
   8   else ()
   9     find_program ( SWIG_EXECUTABLE NAMES swig2.0 swig )
  10     if ( SWIG_EXECUTABLE )
  11       set ( SWIG_USE_FILE ${CMAKE_ROOT}/Modules/UseSWIG.cmake )
  12       set ( SWIG_FOUND TRUE )
  13     endif ()
  14   endif ()
  15   find_package ( PythonLibs )
  16   find_package ( PythonInterp )
  17 endif ()
  18
  19 if ( SWIG_FOUND AND PYTHONLIBS_FOUND AND PYTHONINTERP_FOUND )
  20   include ( UseSWIG )
  21   include_directories ( BEFORE ${CMAKE_SOURCE_DIR}/src )
  22   include_directories ( ${PYTHON_INCLUDE_DIRS} )
  23   link_directories ( ${CMAKE_CURRENT_BINARY_DIR}/../src )
  24
  25   if ( DOCUMENTATION AND DOXYGEN_FOUND )
  26     set(CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
  27   endif()
  28   swig_add_module ( ftdi1 python ftdi1.i )
  29   swig_link_libraries ( ftdi1 ftdi1 )
  30
  31   if ( LINK_PYTHON_LIBRARY )
  32     swig_link_libraries ( ftdi1 ${PYTHON_LIBRARIES} )
  33   elseif( APPLE )
  34     set_target_properties ( ${SWIG_MODULE_ftdi1_REAL_NAME} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup" )
  35   endif ()
  36
  37   set_target_properties ( ${SWIG_MODULE_ftdi1_REAL_NAME} PROPERTIES NO_SONAME ON )
  38
  39   execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; print( sysconfig.get_python_lib( plat_specific=True, prefix='${CMAKE_INSTALL_PREFIX}' ) )"
  40                     OUTPUT_VARIABLE _ABS_PYTHON_MODULE_PATH
  41                     OUTPUT_STRIP_TRAILING_WHITESPACE )
  42
  43   get_filename_component ( _ABS_PYTHON_MODULE_PATH ${_ABS_PYTHON_MODULE_PATH} ABSOLUTE )
  44   file ( RELATIVE_PATH _REL_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX} ${_ABS_PYTHON_MODULE_PATH} )
  45
  46   set ( PYTHON_MODULE_PATH
  47         ${_REL_PYTHON_MODULE_PATH}
  48       )
  49
  50   install ( FILES ${CMAKE_CURRENT_BINARY_DIR}/ftdi1.py DESTINATION ${PYTHON_MODULE_PATH} )
  51   install ( TARGETS ${SWIG_MODULE_ftdi1_REAL_NAME} LIBRARY DESTINATION ${PYTHON_MODULE_PATH} )
  52
  53   if ( DOCUMENTATION AND DOXYGEN_FOUND )
  54       # Run doxygen to only generate the xml
  55       add_custom_command ( OUTPUT ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  56           COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc
  57           COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile.xml
  58           WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  59           DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers}
  60       )
  61
  62       # generate .i from doxygen .xml
  63       add_custom_command ( OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  64           COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
  65               ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  66               ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  67           DEPENDS ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  68       )
  69       add_custom_target ( doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i )
  70       add_dependencies( ${SWIG_MODULE_ftdi1_REAL_NAME} doc_i )
  71
  72   endif ()
  73
  74   set ( LIBFTDI_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX}/${PYTHON_MODULE_PATH} )
  75   set ( LIBFTDI_PYTHON_MODULE_PATH ${LIBFTDI_PYTHON_MODULE_PATH} PARENT_SCOPE ) # for ftdiconfig.cmake
  76   message(STATUS "Building python bindings via swig. Will be installed under ${LIBFTDI_PYTHON_MODULE_PATH}")
  77
  78   add_subdirectory ( examples )
  79 else ()
  80   message(STATUS "Not building python bindings")
  81 endif ()