developer.intra2net.com Git - libftdi/blob - bindings/CMakeLists.txt

   1 option ( PYTHON_BINDINGS "Build python bindings via swig" ON )
   2
   3 if ( PYTHON_BINDINGS )
   4   find_package ( SWIG )
   5   find_package ( PythonLibs )
   6   find_package ( PythonInterp )
   7 endif ()
   8
   9 if ( SWIG_FOUND AND PYTHONLIBS_FOUND AND PYTHONINTERP_FOUND )
  10   include ( UseSWIG )
  11   include_directories ( BEFORE ${CMAKE_SOURCE_DIR}/src )
  12   include_directories ( ${PYTHON_INCLUDE_DIRS} )
  13   link_directories ( ${CMAKE_CURRENT_BINARY_DIR}/../src )
  14
  15   swig_add_module ( ftdi1 python ftdi1.i )
  16   swig_link_libraries ( ftdi1 ftdi1 )
  17
  18   # do not link python modules on debian
  19   # http://www.debian.org/doc/packaging-manuals/python-policy/ch-module_packages.html
  20   if ( NOT UNIX OR ( UNIX AND NOT EXISTS "/etc/debian_version" ) )
  21     swig_link_libraries ( ftdi1 ${PYTHON_LIBRARIES} )
  22   endif ()
  23
  24   execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "import sys; print( '%d.%d' % ( sys.version_info[0], sys.version_info[1] ) )"
  25                     OUTPUT_VARIABLE PYTHON_VERSION
  26                     OUTPUT_STRIP_TRAILING_WHITESPACE )
  27
  28   set ( SITEPACKAGE lib${LIB_SUFFIX}/python${PYTHON_VERSION}/site-packages )
  29
  30   INSTALL ( FILES ${CMAKE_CURRENT_BINARY_DIR}/_ftdi1.so DESTINATION ${SITEPACKAGE} )
  31   INSTALL ( FILES ${CMAKE_CURRENT_BINARY_DIR}/ftdi1.py DESTINATION ${SITEPACKAGE} )
  32
  33   if ( DOCUMENTATION AND DOXYGEN_FOUND )
  34
  35       set(CMAKE_SWIG_FLAGS -DDOXYGEN=${DOXYGEN_FOUND})
  36
  37       # Run doxygen to only generate the xml
  38       add_custom_command ( OUTPUT ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  39           COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc
  40           COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile.xml
  41           WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  42           DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers}
  43       )
  44
  45       # generate .i from doxygen .xml
  46       add_custom_command ( OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  47           COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/doxy2swig.py -n
  48               ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  49               ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i
  50           DEPENDS ${CMAKE_BINARY_DIR}/doc/xml/ftdi_8c.xml
  51       )
  52       add_custom_target ( doc_i DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/ftdi1_doc.i )
  53       add_dependencies( ${SWIG_MODULE_ftdi1_REAL_NAME} doc_i )
  54
  55   endif ()
  56
  57   set ( LIBFTDI_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX}/${SITEPACKAGE} )
  58   set ( LIBFTDI_PYTHON_MODULE_PATH ${LIBFTDI_PYTHON_MODULE_PATH} PARENT_SCOPE ) # for ftdiconfig.cmake
  59   message(STATUS "Building python bindings via swig. Will be installed under ${LIBFTDI_PYTHON_MODULE_PATH}")
  60 else ()
  61   message(STATUS "Not building python bindings")
  62 endif ()