developer.intra2net.com Git - libftdi/blob - CMakeLists.txt

   1 # Project
   2 project(libftdi)
   3 set(MAJOR_VERSION 0)
   4 set(MINOR_VERSION 15)
   5 set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION})
   6 SET(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}")
   7
   8 # CMake
   9 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  10    set(CMAKE_BUILD_TYPE     Debug)
  11 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  12 set(CMAKE_COLOR_MAKEFILE ON)
  13 cmake_minimum_required(VERSION 2.6 FATAL_ERROR)
  14
  15 # Debug build
  16 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  17 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  18    add_definitions(-DDEBUG)
  19 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  20
  21 FIND_PACKAGE(USB REQUIRED)
  22 INCLUDE_DIRECTORIES(${LIBUSB_INCLUDE_DIR})
  23
  24 # Set components
  25 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  26 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  27 set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries")
  28 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  29
  30 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  31 "Shared library for general use.")
  32 set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION
  33 "Static library, good if you want to embed libftdi in your application.")
  34 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  35 "C/C++ header files.")
  36
  37 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  38 set(CPACK_COMPONENT_STATICLIBS_GROUP "Development")
  39 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  40
  41 # Documentation
  42 find_package(Doxygen)
  43 if(DOXYGEN_FOUND)
  44
  45    # Set variables
  46    set(PACKAGE libftdi)
  47    set(VERSION ${VERSION_STRING})
  48    set(top_srcdir ${CMAKE_SOURCE_DIR})
  49
  50    # Find doxy config
  51    message(STATUS "Doxygen found.")
  52    set(DOXY_DIR "${CMAKE_SOURCE_DIR}/doc")
  53    set(DOXY_CONFIG "${DOXY_DIR}/Doxyfile.in")
  54
  55    # Copy doxy.config.in
  56    configure_file("${DOXY_CONFIG}" "${CMAKE_BINARY_DIR}/doxy.config")
  57    add_custom_target(doc "${DOXYGEN_EXECUTABLE}" "doxy.config")
  58
  59 endif(DOXYGEN_FOUND)
  60
  61 # Package information
  62 set(CPACK_PACKAGE_VERSION              ${VERSION_STRING})
  63 set(CPACK_PACKAGE_CONTACT              "Marek Vavrusa <marek@vavrusa.com>")
  64 set(CPACK_PACKAGE_DESCRIPTION          "libftdi library.")
  65 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION}
  66                                        )
  67 # Package settings
  68 if(${UNIX})
  69   set(CPACK_GENERATOR                    "DEB;RPM")
  70   set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
  71   set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
  72   set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION})
  73 endif(${UNIX})
  74
  75 if(${WIN32})
  76   set(CPACK_GENERATOR                    "NSIS")
  77   set(CPACK_CMAKE_GENERATOR              "MinGW Makefiles")
  78   set(CPACK_PACKAGE_NAME                 "${PROJECT_NAME}")
  79   set(CPACK_PACKAGE_VENDOR               "")
  80   set(CPACK_PACKAGE_INSTALL_DIRECTORY    "libftdi")
  81   set(CPACK_PACKAGE_FILE_NAME            "${PROJECT_NAME}-${VERSION_STRING}-win32")
  82   set(CPACK_NSIS_DISPLAY_NAME            "libftdi")
  83   set(CPACK_NSIS_MODIFY_PATH             "ON")
  84 endif(${WIN32})
  85
  86 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/COPYING.LIB)
  87
  88 set(CPACK_SOURCE_GENERATOR             TGZ)
  89 set(CPACK_SOURCE_IGNORE_FILES          "\\\\.git")
  90 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_FILE_NAME})
  91
  92 # Subdirectories
  93 if(${UNIX})
  94   set(CPACK_SET_DESTDIR "ON")
  95 endif(${UNIX})
  96
  97 add_subdirectory(src)
  98 add_subdirectory(ftdipp)
  99 add_subdirectory(examples)
 100 add_subdirectory(packages)
 101
 102 # PkgConfig
 103 set(prefix      ${CMAKE_INSTALL_PREFIX})
 104 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 105 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 106
 107 if(${UNIX})
 108    set(libdir      ${CMAKE_INSTALL_PREFIX}/lib)
 109 endif(${UNIX})
 110 if(${WIN32})
 111    set(libdir      ${CMAKE_INSTALL_PREFIX}/bin)
 112 endif(${WIN32})
 113
 114 configure_file(${CMAKE_SOURCE_DIR}/libftdi.pc.in ${CMAKE_BINARY_DIR}/libftdi.pc @ONLY)
 115 configure_file(${CMAKE_SOURCE_DIR}/libftdipp.pc.in ${CMAKE_BINARY_DIR}/libftdipp.pc @ONLY)
 116 install(FILES ${CMAKE_BINARY_DIR}/libftdi.pc ${CMAKE_BINARY_DIR}/libftdipp.pc
 117         DESTINATION lib/pkgconfig)
 118
 119 if(${UNIX})
 120     configure_file(${CMAKE_SOURCE_DIR}/libftdi-config.in ${CMAKE_BINARY_DIR}/libftdi-config @ONLY)
 121     install(PROGRAMS ${CMAKE_BINARY_DIR}/libftdi-config DESTINATION bin)
 122 endif(${UNIX})
 123
 124 include(CPack)