developer.intra2net.com Git - libftdi/blob - CMakeLists.txt

   1 # Project
   2 project(libftdi1)
   3 set(MAJOR_VERSION 1)
   4 set(MINOR_VERSION 0)
   5 set(PACKAGE libftdi1)
   6 set(VERSION_STRING ${MAJOR_VERSION}.${MINOR_VERSION})
   7 set(VERSION ${VERSION_STRING})
   8 set ( CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake )
   9
  10 # CMake
  11 if("${CMAKE_BUILD_TYPE}" STREQUAL "")
  12    set(CMAKE_BUILD_TYPE     RelWithDebInfo)
  13 endif("${CMAKE_BUILD_TYPE}" STREQUAL "")
  14 set(CMAKE_COLOR_MAKEFILE ON)
  15 cmake_minimum_required(VERSION 2.6 FATAL_ERROR)
  16
  17 add_definitions(-Wall)
  18
  19 # Debug build
  20 message("-- Build type: ${CMAKE_BUILD_TYPE}")
  21 if(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  22    add_definitions(-DDEBUG)
  23 endif(${CMAKE_BUILD_TYPE} STREQUAL Debug)
  24
  25 # find libusb
  26 find_package ( USB1 REQUIRED )
  27 include_directories ( ${LIBUSB_INCLUDE_DIR} )
  28
  29 # Find Boost (optional package)
  30 find_package(Boost)
  31
  32 # Set components
  33 set(CPACK_COMPONENTS_ALL sharedlibs staticlibs headers)
  34 set(CPACK_COMPONENT_SHAREDLIBS_DISPLAY_NAME "Shared libraries")
  35 set(CPACK_COMPONENT_STATICLIBS_DISPLAY_NAME "Static libraries")
  36 set(CPACK_COMPONENT_HEADERS_DISPLAY_NAME "C++ Headers")
  37
  38 set(CPACK_COMPONENT_SHAREDLIBS_DESCRIPTION
  39 "Shared library for general use.")
  40 set(CPACK_COMPONENT_STATICLIBS_DESCRIPTION
  41 "Static library, good if you want to embed libftdi1 in your application.")
  42 set(CPACK_COMPONENT_HEADERS_DESCRIPTION
  43 "C/C++ header files.")
  44
  45 set(CPACK_COMPONENT_SHAREDLIBS_GROUP "Development")
  46 set(CPACK_COMPONENT_STATICLIBS_GROUP "Development")
  47 set(CPACK_COMPONENT_HEADERS_GROUP    "Development")
  48
  49 option ( STATICLIBS "Build static libraries" ON )
  50
  51 # guess LIB_SUFFIX, don't take debian multiarch into account
  52 if ( NOT DEFINED LIB_SUFFIX )
  53   if ( CMAKE_SYSTEM_NAME MATCHES "Linux" AND NOT CMAKE_CROSSCOMPILING AND NOT EXISTS "/etc/debian_version" )
  54     if ( "${CMAKE_SIZEOF_VOID_P}" EQUAL "8" )
  55       set ( LIB_SUFFIX 64 )
  56     endif ()
  57   endif ()
  58 endif ()
  59
  60 if(NOT APPLE)
  61   if(CMAKE_SIZEOF_VOID_P EQUAL 4)
  62       SET(PACK_ARCH "")
  63     else(CMAKE_SIZEOF_VOID_P EQUAL 8)
  64       SET(PACK_ARCH .x86_64)
  65   endif(CMAKE_SIZEOF_VOID_P EQUAL 4)
  66 else(NOT APPLE)
  67   SET(PACK_ARCH "")
  68 endif(NOT APPLE)
  69
  70 # Package information
  71 set(CPACK_PACKAGE_VERSION              ${VERSION_STRING})
  72 set(CPACK_PACKAGE_CONTACT              "Intra2net AG <libftdi@developer.intra2net.com>")
  73 set(CPACK_PACKAGE_DESCRIPTION          "libftdi1 library.")
  74 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  ${CPACK_PACKAGE_DESCRIPTION}
  75                                        )
  76 # Package settings
  77 if ( UNIX )
  78   set(CPACK_GENERATOR                    "DEB;RPM")
  79   set(CPACK_CMAKE_GENERATOR              "Unix Makefiles")
  80   set(CPACK_PACKAGE_NAME                 ${PROJECT_NAME})
  81   set(CPACK_PACKAGE_FILE_NAME            ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}${PACK_ARCH})
  82 endif ()
  83
  84 if ( WIN32 )
  85   set ( CPACK_GENERATOR                    "NSIS" )
  86   set ( CPACK_CMAKE_GENERATOR              "MinGW Makefiles" )
  87   set ( CPACK_PACKAGE_NAME                 "${PROJECT_NAME}" )
  88   set ( CPACK_PACKAGE_VENDOR               "" )
  89   set ( CPACK_PACKAGE_INSTALL_DIRECTORY    "libftdi1" )
  90   set ( CPACK_PACKAGE_FILE_NAME            "${PROJECT_NAME}-${VERSION_STRING}-win32")
  91   set ( CPACK_NSIS_DISPLAY_NAME            "libftdi1" )
  92   set ( CPACK_NSIS_MODIFY_PATH             ON )
  93 endif ()
  94
  95 set(CPACK_RESOURCE_FILE_LICENSE        ${CMAKE_SOURCE_DIR}/LICENSE)
  96
  97 set(CPACK_SOURCE_GENERATOR             TGZ)
  98 set(CPACK_SOURCE_IGNORE_FILES          "\\\\.git;~$;build/")
  99 set(CPACK_SOURCE_PACKAGE_FILE_NAME     ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION})
 100
 101 # Subdirectories
 102 if ( UNIX )
 103   set ( CPACK_SET_DESTDIR ON )
 104 endif ()
 105
 106 # "make dist" target
 107 set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION_STRING})
 108 add_custom_target(dist
 109     COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
 110             | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
 111     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
 112
 113
 114 # Documentation
 115 option ( DOCUMENTATION "Generate API documentation with Doxygen" ON )
 116
 117
 118 find_package ( Doxygen )
 119 if ( DOCUMENTATION AND DOXYGEN_FOUND )
 120
 121    # Find doxy config
 122    message(STATUS "Doxygen found.")
 123
 124    # Copy doxy.config.in
 125    set(top_srcdir ${CMAKE_SOURCE_DIR})
 126    configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.in ${CMAKE_BINARY_DIR}/Doxyfile )
 127    configure_file(${CMAKE_SOURCE_DIR}/doc/Doxyfile.xml.in ${CMAKE_BINARY_DIR}/Doxyfile.xml )
 128
 129    # Run doxygen
 130    add_custom_command(
 131     OUTPUT ${CMAKE_BINARY_DIR}/doc/html/index.html
 132     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/doc
 133     COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile
 134     DEPENDS ${c_headers};${c_sources};${cpp_sources};${cpp_headers}
 135    )
 136
 137    add_custom_target(docs ALL DEPENDS ${CMAKE_BINARY_DIR}/doc/html/index.html)
 138
 139    message(STATUS "Generating API documentation with Doxygen")
 140 else(DOCUMENTATION AND DOXYGEN_FOUND)
 141    message(STATUS "Not generating API documentation")
 142 endif(DOCUMENTATION AND DOXYGEN_FOUND)
 143
 144 add_subdirectory(src)
 145 add_subdirectory(ftdipp)
 146 add_subdirectory(python)
 147 add_subdirectory(ftdi_eeprom)
 148 add_subdirectory(examples)
 149 add_subdirectory(packages)
 150 add_subdirectory(test)
 151
 152 # PkgConfig
 153 set(prefix      ${CMAKE_INSTALL_PREFIX})
 154 set(exec_prefix ${CMAKE_INSTALL_PREFIX}/bin)
 155 set(includedir  ${CMAKE_INSTALL_PREFIX}/include/${PROJECT_NAME})
 156
 157 if(${UNIX})
 158    set(libdir      ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
 159 endif(${UNIX})
 160 if(${WIN32})
 161    set(libdir      ${CMAKE_INSTALL_PREFIX}/bin)
 162 endif(${WIN32})
 163
 164 configure_file(${CMAKE_SOURCE_DIR}/libftdi1.spec.in ${CMAKE_BINARY_DIR}/libftdi1.spec @ONLY)
 165 configure_file(${CMAKE_SOURCE_DIR}/libftdi1.pc.in ${CMAKE_BINARY_DIR}/libftdi1.pc @ONLY)
 166 configure_file(${CMAKE_SOURCE_DIR}/libftdipp1.pc.in ${CMAKE_BINARY_DIR}/libftdipp1.pc @ONLY)
 167 install(FILES ${CMAKE_BINARY_DIR}/libftdi1.pc ${CMAKE_BINARY_DIR}/libftdipp1.pc
 168         DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 169
 170 if ( UNIX )
 171   configure_file ( libftdi1-config.in ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config @ONLY )
 172   install ( PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/libftdi1-config
 173             DESTINATION bin )
 174
 175   # config script install path
 176   if ( NOT DEFINED LIBFTDI_CMAKE_CONFIG_DIR )
 177     set ( LIBFTDI_CMAKE_CONFIG_DIR lib${LIB_SUFFIX}/cmake/libftdi1 )
 178   endif ()
 179
 180   set ( LIBFTDI_INCLUDE_DIR ${includedir} )
 181   set ( LIBFTDI_INCLUDE_DIRS ${LIBFTDI_INCLUDE_DIR} )
 182   get_target_property( _LIBFTDI_LIBRARY_LOCATION ftdi1 LOCATION )
 183   get_filename_component ( _LIBFTDI_LIBRARY_NAME ${_LIBFTDI_LIBRARY_LOCATION} NAME )
 184   set ( LIBFTDI_LIBRARY ${libdir}/${_LIBFTDI_LIBRARY_NAME} )
 185   set ( LIBFTDI_LIBRARIES ${LIBFTDI_LIBRARY} )
 186   list ( APPEND LIBFTDI_LIBRARIES ${LIBUSB_LIBRARIES} )
 187   get_target_property( _LIBFTDIPP_LIBRARY_LOCATION ftdipp1 LOCATION )
 188   get_filename_component ( _LIBFTDIPP_LIBRARY_NAME ${_LIBFTDIPP_LIBRARY_LOCATION} NAME )
 189   set ( LIBFTDIPP_LIBRARY ${libdir}/${_LIBFTDIPP_LIBRARY_NAME} )
 190   set ( LIBFTDIPP_LIBRARIES ${LIBFTDIPP_LIBRARY} )
 191   list ( APPEND LIBFTDIPP_LIBRARIES ${LIBUSB_LIBRARIES} )
 192   set ( LIBFTDI_ROOT_DIR ${prefix} )
 193   set ( LIBFTDI_VERSION_STRING ${VERSION_STRING} )
 194   set ( LIBFTDI_VERSION_MAJOR ${MAJOR_VERSION} )
 195   set ( LIBFTDI_VERSION_MINOR ${MINOR_VERSION} )
 196
 197   set ( LIBFTDI_USE_FILE ${CMAKE_INSTALL_PREFIX}/${LIBFTDI_CMAKE_CONFIG_DIR}/UseLibFTDI1.cmake )
 198   configure_file ( LibFTDI1Config.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake @ONLY )
 199   install ( FILES ${CMAKE_CURRENT_BINARY_DIR}/LibFTDI1Config.cmake cmake/UseLibFTDI1.cmake
 200             DESTINATION ${LIBFTDI_CMAKE_CONFIG_DIR}
 201           )
 202 endif ()
 203
 204 include(CPack)